gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/aesara: Bump to 2.5.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-03-15 09:02:36 +01:00
parent 80a54fcb2f
commit d8025818bc
2 changed files with 74 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/aesara/Manifest
View File

@@ -1,2 +1,3 @@
DIST aesara-rel-2.3.8.tar.gz 8188314 BLAKE2B 9a2e43082a19e432aaab3300fc0c6a0cc96644b00c4646ae7a509cb00cc93e8125cd73e8ed4b341197b7225c66aa33b6156ba034946610aefe178fb0aecc5ce2 SHA512 9ba0ef46e4d51f8a04edcf347e539978e357d839147307127e0c01cbc25f013a00c5d720153c58142194dd38f91c34afbc366029a163f90ab036efbea7f939af
DIST aesara-rel-2.4.0.tar.gz 8189236 BLAKE2B 05fd50ddd64ec063b3ea226706d232648e0fc314b754342db9537f1d55abd71a65afee3b3934b41e182fe12c224c8e10e8235ac58ba91c4c9f28d3ad8df1b7ac SHA512 b58e881145e051f97d5065fd46716209e280de46bd49ce6d1294880137aefc550741c6f96a47c8e2dbb54717d7c9f161a92f2cb5d3535687fbb6115641cc714c
DIST aesara-rel-2.5.1.tar.gz 8187340 BLAKE2B d31835b7f1e7268992e5686dea250793c673d059a3b8e48ef7d3900c667815f63c10fe85e8e306191962ed4f1488dc01664a932161a55dd9b2110c16b5f3807a SHA512 962055ac60bcd1e4a980ee7393074b9b7e33cc510d06198e8570d43951696aab44d71579be890ae76420384b2bda5964656a667c5e0fb0b46cd9c1cc189b74ca

73
dev-python/aesara/aesara-2.5.1.ebuild Normal file
View File

@@ -0,0 +1,73 @@
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 multiprocessing optfeature
MY_P=aesara-rel-${PV}
DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
HOMEPAGE="https://github.com/aesara-devs/aesara"
SRC_URI="https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
RDEPEND="
dev-python/cons[${PYTHON_USEDEP}]
dev-python/etuples[${PYTHON_USEDEP}]
dev-python/logical-unification[${PYTHON_USEDEP}]
dev-python/minikanren[${PYTHON_USEDEP}]
dev-python/filelock[${PYTHON_USEDEP}]
>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/typing-extensions[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# speed tests are unreliable
tests/scan/test_basic.py::test_speed
tests/scan/test_basic.py::test_speed_rnn
tests/scan/test_basic.py::test_speed_batchrnn
tests/link/test_vm.py::test_speed
tests/link/test_vm.py::test_speed_lazy
tests/tensor/test_gc.py::test_merge_opt_runtime
# rounding problem?
# https://github.com/aesara-devs/aesara/issues/477
tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
)
local EPYTEST_IGNORE=(
# we do not package numba
tests/link/test_numba.py
tests/link/test_numba_performance.py
)
epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}
python_compile() {
distutils-r1_python_compile
rm "${BUILD_DIR}/install$(python_get_sitedir)/bin/__init__.py" || die
}
pkg_postinst() {
optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
}