media-gfx/imagemagick: add 6.9.13.30

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2025-10-11 12:11:18 +01:00
parent e7348c6f8f
commit d7dd37fe73
2 changed files with 258 additions and 0 deletions
+1
View File
@@ -1,4 +1,5 @@
DIST ImageMagick-6.9.13-25.tar.xz 9616976 BLAKE2B d54d907893fd0901530c989fdf8edc55f5a6513ae39bac9020292d865549839af4651c57aca0e24818feeb82fef5a45fb1b28009d632f5261101761037e111c6 SHA512 57e026f96ffb5022cf1a195fa32acf64b767d739e5cc3f4adc1a3315fb5c9b1146c8ec885eee30e0b4d381b8f6727aa3c57cd758d47b4e6d78e9c2837b8e5250
DIST ImageMagick-6.9.13-29.tar.xz 9628468 BLAKE2B 8b5c7335b7f1968e1c84424a192f170dd0e6beddf8c5fa616fabe06d1e6a185b16f97c35655082d7e6c27190e5294853416e517190124d45211f53140b8a6990 SHA512 41aa141ea7acac52adc344529080ce2d41c71f48bc067e9bd5c49fc285d243940ffb6e34930cea6ef31550ddf6c2dc970c9032104dccba5504d681360b09eded
DIST ImageMagick-6.9.13-30.tar.xz 9628836 BLAKE2B 11c5c1f8130f486e756259cfa44968e73e0ddf2f814f64a8061d1443336b5a03d8c0aad17eb93fa62103795a58b2e263a3ae9cb3f62c5ed35466b1ea72e77958 SHA512 eeb6ce3a6267a4aea4c0ebfe68036a01e8747c53da9df0a353695bc92f99a282375dadfc9b56207622b60f0fe51084fcadda0ac96940dac2aaf970c3ed66f491
DIST ImageMagick-7.1.1-47.tar.xz 10773968 BLAKE2B 0bd2287d9e7247f3b5422649c8235b89be552ef17565ab06e0ac77f00c589b2b87e89733d8fd19185b4438f27c5fa64d293bde118a8b67d7a8352221e1312798 SHA512 35fb786677fc0095cd999a9246c8ebd2af2a3a84fcba9c490c88cc33b1227b02ea9bf5b57b45d253b90d4292ae541bc521eb331f839f5aeeb11802d8e6e0ed35
DIST ImageMagick-7.1.2-3.tar.xz 10786124 BLAKE2B 256e89b875948ee1cb0f6c1cef29d63a4ba7e70f8b47035604932ef2f0e0b7ceb0d9bece9f1783294ad44d9c9de4ac55bcd09a430e5bb09c88da0cef7a76666f SHA512 9789e18be3ef0ff309de5497b31761f765b51e6164d568106f1cb0178427dae53871c246b491de27a63d1fcabf75fc5b8a2ae5915f61a0d801427080c18561e4
@@ -0,0 +1,257 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GENTOO_DEPEND_ON_PERL="no"
QA_PKGCONFIG_VERSION=$(ver_cut 1-3)
inherit flag-o-matic libtool perl-module toolchain-funcs
if [[ ${PV} == 9999 ]] ; then
EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick6.git"
inherit git-r3
MY_P="imagemagick-9999"
else
MY_PV="$(ver_rs 3 '-')"
MY_P="ImageMagick-${MY_PV}"
SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
fi
S="${WORKDIR}/${MY_P}"
DESCRIPTION="A collection of tools and libraries for many image formats"
HOMEPAGE="https://imagemagick.org/index.php"
LICENSE="imagemagick"
# Please check this on bumps, SONAME is often not updated! Use abidiff on old/new.
# If ABI is broken, change the bit after the '-'.
SLOT="0/$(ver_cut 1-3)-0"
IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hardened hdri heif"
IUSE+=" jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl ${GENTOO_PERL_USESTRING}"
IUSE+=" +png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf"
IUSE+=" X xml zlib"
REQUIRED_USE="
corefonts? ( truetype )
svg? ( xml )
test? ( corefonts )
"
RESTRICT="!test? ( test )"
RDEPEND="
!media-gfx/graphicsmagick[imagemagick]
dev-libs/libltdl
bzip2? ( app-arch/bzip2 )
corefonts? ( media-fonts/corefonts )
djvu? ( app-text/djvu )
fftw? ( sci-libs/fftw:3.0 )
fontconfig? ( media-libs/fontconfig )
fpx? ( >=media-libs/libfpx-1.3.0-r1 )
graphviz? ( media-gfx/graphviz )
heif? ( media-libs/libheif:=[x265] )
jbig? ( >=media-libs/jbigkit-2:= )
jpeg? ( media-libs/libjpeg-turbo:= )
jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
lcms? ( media-libs/lcms:2= )
lqr? ( media-libs/liblqr )
opencl? ( virtual/opencl )
openexr? ( media-libs/openexr:0= )
pango? ( x11-libs/pango )
perl? (
${GENTOO_PERL_DEPSTRING}
>=dev-lang/perl-5.8.8:=
)
png? ( media-libs/libpng:= )
postscript? ( app-text/ghostscript-gpl:= )
raw? ( media-libs/libraw:= )
svg? (
gnome-base/librsvg
media-gfx/potrace
)
tiff? ( media-libs/tiff:= )
truetype? (
media-fonts/urw-fonts
>=media-libs/freetype-2
)
webp? ( media-libs/libwebp:= )
wmf? ( media-libs/libwmf )
X? (
x11-libs/libICE
x11-libs/libSM
x11-libs/libXext
x11-libs/libXt
)
xml? ( dev-libs/libxml2:= )
lzma? ( app-arch/xz-utils )
zlib? ( sys-libs/zlib:= )
"
DEPEND="
${RDEPEND}
X? ( x11-base/xorg-proto )
"
BDEPEND="virtual/pkgconfig"
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
default
# for Darwin modules
elibtoolize
# For testsuite, see bug #500580#c3
local ati_cards mesa_cards nvidia_cards render_cards
shopt -s nullglob
ati_cards=$(echo -n /dev/ati/card*)
for card in ${ati_cards[@]} ; do
addpredict "${card}"
done
mesa_cards=$(echo -n /dev/dri/card*)
for card in ${mesa_cards[@]} ; do
addpredict "${card}"
done
nvidia_cards=$(echo -n /dev/nvidia*)
for card in ${nvidia_cards[@]} ; do
addpredict "${card}"
done
render_cards=$(echo -n /dev/dri/renderD128*)
for card in ${render_cards[@]} ; do
addpredict "${card}"
done
shopt -u nullglob
addpredict /dev/nvidiactl
}
src_configure() {
local depth=16
use q8 && depth=8
use q32 && depth=32
use perl && perl_check_env
[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
# Workaround for bug #941208 (gcc PR117100)
tc-is-gcc && [[ $(gcc-major-version) == 13 ]] && append-flags -fno-unswitch-loops
local myeconfargs=(
$(use_enable static-libs static)
$(use_enable hdri)
$(use_enable opencl)
$(use_enable openmp)
--with-threads
--with-modules
--with-quantum-depth=${depth}
$(use_with cxx magick-plus-plus)
$(use_with perl)
--with-perl-options='INSTALLDIRS=vendor'
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
$(use_with bzip2 bzlib)
$(use_with X x)
$(use_with zlib)
--without-autotrace
$(use_with postscript dps)
$(use_with djvu)
--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
$(use_with fftw)
$(use_with fpx)
$(use_with fontconfig)
$(use_with truetype freetype)
$(use_with postscript gslib)
$(use_with graphviz gvc)
$(use_with heif heic)
$(use_with jbig)
$(use_with jpeg)
$(use_with jpeg2k openjp2)
$(use_with lcms)
$(use_with lqr)
$(use_with lzma)
$(use_with openexr)
$(use_with pango)
$(use_with png)
$(use_with raw)
$(use_with svg rsvg)
$(use_with tiff)
$(use_with webp)
$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
$(use_with wmf)
$(use_with xml)
--with-gcc-arch=no-automagic
# Default upstream (as of 6.9.12.96/7.1.1.18 anyway) is open
# For now, let's make USE=hardened do 'limited', and have USE=-hardened
# reflect the upstream default of 'open'.
#
# We might change it to 'secure' and 'limited' at some point.
# See also bug #716674.
--with-security-policy=$(usex hardened limited open)
)
CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
}
src_compile() {
# Avoid perl-module_src_compile
default
}
src_test() {
# Install default (unrestricted) policy in ${HOME} for test suite, bug #664238
local _im_local_config_home="${HOME}/.config/ImageMagick"
mkdir -p "${_im_local_config_home}" || \
die "Failed to create IM config dir in '${_im_local_config_home}'"
cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
local im_command= IM_COMMANDS=()
IM_COMMANDS+=( "identify -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
IM_COMMANDS+=( "identify -list policy" ) # Verify that policy.xml is used
IM_COMMANDS+=( "emake check" ) # Run tests
for im_command in "${IM_COMMANDS[@]}"; do
eval "${S}"/magick.sh \
${im_command} || \
die "Failed to run \"${im_command}\""
done
}
src_install() {
# Ensure documentation installation files and paths with each release!
emake \
DESTDIR="${D}" \
DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
install
rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
dodoc {AUTHORS,README}.txt
if use perl; then
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
fi
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
# .la files in parent are not needed, keep plugin .la files
find "${ED}"/usr/$(get_libdir)/ -maxdepth 1 -name "*.la" -delete || die
if use opencl; then
cat <<-EOF > "${T}"/99${PN}
SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/card0:/dev/dri/renderD128"
EOF
insinto /etc/sandbox.d
# bug #472766
doins "${T}"/99${PN}
fi
insinto /usr/share/${PN}
doins config/*icm
}