dev-python/eventlet: Bump to 0.31.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/eventlet/Manifest

@@ -1,2 +1,3 @@
 DIST eventlet-0.30.0.tar.gz 401035 BLAKE2B 94a272ce810b28c00fc8a468f160e38f3c58c98750455e5eb096c266c46257a7e30e0278a6a8f509e47e6ab40297129ccf52b347a723037f9cc9b85a3e06a203 SHA512 c2ba283063333e9e74536dcda33276f98f74051ea0e9c8669506d2e3b11715f37cd5963af6130f14761a42cc6c8346e59c756efe2cef0ea3547dc30ccb8bf0fb
 DIST eventlet-0.30.2.tar.gz 401552 BLAKE2B 89291efde90d106a96eebd4ea4a892eeb005d6850262b28f7a4508f4f3ccfb9b49dc392dcb6eb0cf20c5d171d26d2a6639627188c97123546162e4e8c61c464d SHA512 af31a7b126f2120dd77699dcf25c7134af1bcf664f40b2422238a3d2120457d5a4d5764e23016ce209882a8b888f94d2776fe194c33092f4a33111b2ac8f0cf1
+DIST eventlet-0.31.0.tar.gz 402530 BLAKE2B d4d5983b22d04fbd6102b7e1ebe58c6e23cba04968478808445d946a3d8fc9ee0b668e83321397163d507cacf58f0cdd8547b0fb2649bad23819fbee0a6cc5ad SHA512 1721ec5d3c6c02361a5993237426d0466d87327e3d429d7b9f20d3466eebf08c60e57a2b1ab133956fe508835e5e84c52317aa51f962e8487f22a6207bbbfcf8

dev-python/eventlet/eventlet-0.31.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit distutils-r1
+
+DESCRIPTION="Highly concurrent networking library"
+HOMEPAGE="https://pypi.org/project/eventlet/ https://github.com/eventlet/eventlet/"
+SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+	<dev-python/dnspython-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	virtual/python-greenlet[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	doc? ( >=dev-python/python-docs-2.7.6-r1:2.7 )
+	test? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/eventlet-0.25.1-tests.patch"
+	"${FILESDIR}/eventlet-0.30.0-tests-socket.patch"
+	"${FILESDIR}/eventlet-0.30.2-test-timeout.patch"
+)
+
+distutils_enable_sphinx doc
+distutils_enable_tests nose
+
+python_prepare_all() {
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version -b dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'https://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" doc/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	unset PYTHONPATH
+	export TMPDIR="${T}"
+	nosetests -v -x || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}