net-misc/electrum: Bump to 4.5.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-10-23 08:16:14 +02:00
parent 6100b78e84
commit d7b32ecb42
2 changed files with 119 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST electrum-4.5.5.gh.tar.gz 4927614 BLAKE2B 9b0bdf4f79ed15279bd8485b9d7fd1d911a5cdc6c3a2deb5e72dad7cd232c87d3f41f10ab572ab3969c9d1ddc65742d1983369a43946ab7f321d49975a50b41a SHA512 28121665cad7bc540600562d4d3e72e20108785c096647fdcc9eb8c26616a04730f53ba53b19f6a332eadc8e20a5524b33dab3719421aeb2b51a0531f9e8ef11
DIST electrum-4.5.6.gh.tar.gz 5893660 BLAKE2B e1d79b64709995b2d8768afe4961a16e930502dcc79167dc1e4f8a53f3cb2573df466b3af4b4863bb4fea21cb2ce383a277f08e49d6b935fefaff0377070bf0f SHA512 b9a146ca6d4b29b215bb4bf6ad865856c3b8067d90c42fd740f3805aa37fc46f9072c2929401150b76423143ad63087da01b120bce591865d5f0f34cba941943
DIST electrum-4.5.8.gh.tar.gz 5896794 BLAKE2B a58a62adfdfe9d3f033033f9120e697cb2c2441076abfc7e914ad7185b9bbe63d81e2c305b80ab57cd0649274f9077f3c4ae59d6236a0bb23ad6838553186894 SHA512 0e7b15747fcce94ad60f068c013a5f6051402b049bb63493179768f6a4c6cb7b8d1b7b1750861afd89f7ed6a83313dee6d40022098ed2dbb9897fbf31e978350
+118
View File
@@ -0,0 +1,118 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
PYTHON_REQ_USE="ncurses?"
inherit distutils-r1 xdg-utils
DESCRIPTION="User friendly Bitcoin client"
HOMEPAGE="
https://electrum.org/
https://github.com/spesmilo/electrum/
"
SRC_URI="
https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cli ncurses qrcode +qt5"
REQUIRED_USE="|| ( cli ncurses qt5 )"
RDEPEND="
${PYTHON_DEPS}
dev-libs/libsecp256k1
>=dev-python/aiohttp-socks-0.8.4[${PYTHON_USEDEP}]
=dev-python/aiorpcx-0.23*[${PYTHON_USEDEP}]
>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
>=dev-python/dnspython-2[${PYTHON_USEDEP}]
dev-python/jsonpatch[${PYTHON_USEDEP}]
dev-python/pbkdf2[${PYTHON_USEDEP}]
dev-python/pyperclip[${PYTHON_USEDEP}]
dev-python/PySocks[${PYTHON_USEDEP}]
dev-python/qrcode[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
>=dev-python/protobuf-python-3.20[${PYTHON_USEDEP}]
qrcode? ( media-gfx/zbar[v4l] )
qt5? (
dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
)
ncurses? ( $(python_gen_impl_dep 'ncurses') )
"
BDEPEND="
test? (
dev-python/pyaes[${PYTHON_USEDEP}]
dev-python/pycryptodome[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
EPYTEST_IGNORE=(
# test for qml/PyQt6 GUI that doesn't work anyway
tests/test_qml_types.py
)
src_prepare() {
# use backwards-compatible cryptodome API
sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
# make qdarkstyle dep optional
sed -i -e '/qdarkstyle/d' contrib/requirements/requirements.txt || die
# remove upper bounds from deps
sed -i -e 's:,<[0-9.]*::' contrib/requirements/requirements.txt || die
local bestgui
if use qt5; then
bestgui=qt
elif use ncurses; then
bestgui=text
else
bestgui=stdio
fi
sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
eapply_user
xdg_environment_reset
distutils-r1_src_prepare
}
src_install() {
dodoc RELEASE-NOTES
distutils-r1_src_install
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
local v
for v in ${REPLACING_VERSIONS}; do
ver_test "${v}" -ge 4.3.4 && return
done
ewarn "If you are new to BitCoin, please be aware that:"
ewarn "1. Cryptocurrencies are volatile. BTC has been subject to rapid"
ewarn " changes of value in the past."
ewarn "2. Cryptocurrency ownership is determined solely by the access to"
ewarn " the private key. If the key is lost or stolen, BTC are unrevocably"
ewarn " lost."
ewarn "3. Proof-of-work based cryptocurrencies have negative environmental"
ewarn " impact. BTC mining is consuming huge amounts of electricity."
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}