dev-vcs/tig: Add version bump 2.3.0

Closes: https://bugs.gentoo.org/632530
Closes: https://github.com/gentoo/gentoo/pull/5826

dev-vcs/tig/Manifest

@@ -1 +1,2 @@
 DIST tig-2.2.2.tar.gz 1046910 SHA256 316214d87f7693abc0cbe8ebbb85decdf5e1b49d7ad760ac801af3dd73385e35 SHA512 e43cf8b4e7938342b581a1238222d5cbf62e242208cd65fc9b3261c4076b7c60c182f9a80613538fcf8b50187cc2844c22f6d1aeaaa8b23864670667a91dbfcd WHIRLPOOL c4f569d969bacdea8f7a765acfced6c45b04f36c5eca915702c369de1ab11dbe4d8c01934852d40ffdd641dcbf5ed699803c67ea3deccf539721dba46ca23716
+DIST tig-2.3.0.tar.gz 1080956 SHA256 686f0386927904dc6410f0b1a712cb8bd7fff3303f688d7dc43162f4ad16c0ed SHA512 d5e8bf04689fdbeab4f2ee60eef1e8e7686827228dc2f87b20c40a3a1c31aa3476d5088423ba8bcb72616a9f0f211a2dbb631a72cc946553e41cb225ea60ab37 WHIRLPOOL d7ff8b990b6ebf0fda6df28624bee7e842103047490e037ad562f873740f2358e66ccaf429af7caf0319f06b0f92600f0c04733054aeffc14026a95060abfbc3

dev-vcs/tig/tig-2.3.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/jonas/tig.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://github.com/jonas/tig/releases/download/${P}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+fi
+
+DESCRIPTION="A text mode interface for git"
+HOMEPAGE="https://jonas.github.io/tig/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="unicode"
+
+DEPEND="
+	sys-libs/ncurses:0=[unicode?]
+	sys-libs/readline:0="
+RDEPEND="${DEPEND}
+	dev-vcs/git"
+[[ ${PV} == "9999" ]] && DEPEND+=" app-text/asciidoc app-text/xmlto"
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf $(use_with unicode ncursesw)
+}
+
+src_compile() {
+	emake V=1
+	[[ ${PV} == "9999" ]] && emake V=1 doc-man doc-html
+}
+
+src_test() {
+	# workaround parallel test failures
+	emake -j1 test
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-doc-man
+	dodoc doc/manual.html README.html NEWS.html
+	newbashcomp contrib/tig-completion.bash ${PN}
+
+	docinto examples
+	dodoc contrib/*.tigrc
+}