net-libs/libnetfilter_log: fix LICENSE, delete unused libtool files

Closes: https://bugs.gentoo.org/840972
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/38436
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

net-libs/libnetfilter_log/libnetfilter_log-1.0.2-r1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info verify-sig
+
+DESCRIPTION="Interface to packets that have been logged by the kernel packet filter"
+HOMEPAGE="https://www.netfilter.org/projects/libnetfilter_log/"
+SRC_URI="https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2
+	verify-sig? ( https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2.sig )"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~sparc ~x86"
+IUSE="doc"
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/netfilter.org.asc
+
+RDEPEND=">=net-libs/libnfnetlink-1.0.0
+	>=net-libs/libmnl-1.0.3"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	verify-sig? ( sec-keys/openpgp-keys-netfilter )"
+
+CONFIG_CHECK="~NETFILTER_NETLINK_LOG"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	kernel_is lt 2 6 14 && die "requires at least 2.6.14 kernel version"
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc html-doc) \
+		$(use_enable doc man-pages)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}