dev-python/elasticsearch: Bump to 8.15.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/elasticsearch/Manifest

@@ -1 +1,2 @@
 DIST elasticsearch-py-8.14.0.gh.tar.gz 1092912 BLAKE2B 4ee556bc475d63e33cec318936b2dbf8b280236bcdfe28bc90a4beb7e1d024b8d63180c29e42096cb32bf3da7c771532c57190d763651118603779f816e95656 SHA512 9e9821102659b4c877959e25c33e1b1942f6eabe62bb6de73cda4875c248b0f9285d948e535e9426ca42552f7aa3e75c459f991bfa574c1d8400d78486ee5493
+DIST elasticsearch-py-8.15.0.gh.tar.gz 1163528 BLAKE2B 8ee26e504f09b4ed2ccd695c034f5e35bdc609c1de7055b1f93f279edc7b3b6ac72625e8645c25d126481d7d877a197ecb8d7b35771841b412291caa42d4ee5f SHA512 7982f8366d7b74c85fdcaf4761fcbd9e6e14f0ef2a4aff353bad0b5bbedf7251eabf933e86f1dc9734de0aa6d43a30e1f055cd3b9c7ff2c7864da8779f64bfbc

dev-python/elasticsearch/elasticsearch-8.15.0.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..12} )
+
+inherit distutils-r1
+
+MY_P="elasticsearch-py-${PV}"
+DESCRIPTION="Official Elasticsearch client library for Python"
+HOMEPAGE="
+	https://ela.st/es-python
+	https://github.com/elastic/elasticsearch-py/
+	https://pypi.org/project/elasticsearch/
+"
+SRC_URI="
+	https://github.com/elastic/elasticsearch-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+	<dev-python/elastic-transport-9[${PYTHON_USEDEP}]
+	>=dev-python/elastic-transport-8.13[${PYTHON_USEDEP}]
+	>=dev-python/orjson-3[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-sdk[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+		dev-python/unasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/sphinx-autodoc-typehints \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# REST api tests are a black hole for effort. It downloads the tests
+		# so its an ever moving target. It also requires effort to blacklist
+		# tests for apis which are license restricted.
+		"test_elasticsearch/test_server/test_rest_api_spec.py"
+		# Counting deprecation warnings from python is bound to fail even
+		# if all are fixed in this package. Not worth it.
+		"test_elasticsearch/test_client/test_deprecated_options.py"
+		# Running daemon for tests is finicky and upstream CI fails at it
+		# as well.
+		"test_elasticsearch/test_server/"
+		"test_elasticsearch/test_async/test_server/"
+	)
+
+	local -x TEST_WITH_OTEL=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -p asyncio
+}