sys-apps/texinfo: Add useflag xs (default off) toggling C in Perl

When pure Perl is used, texinfo will be slower, however, there is no need for
rebuilds on Perl upgrade. Since this is our most frequent road bump at the
moment, see portage bug 638914, we take the slowdown by default and hope that
things improve. Not sure how well this will work out, however, since texinfo
again depends on other Perl modules, which are installed in version dependent
paths.

Bug: https://bugs.gentoo.org/638914
Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
This commit is contained in:
Andreas K. Hüttel
2019-06-05 04:30:17 +02:00
parent d8aeaed593
commit d6e0516dee
2 changed files with 54 additions and 0 deletions
+7
View File
@@ -5,4 +5,11 @@
<email>base-system@gentoo.org</email>
<name>Gentoo Base System</name>
</maintainer>
<maintainer type="project">
<email>perl@gentoo.org</email>
<name>Gentoo Perl Project</name>
</maintainer>
<use>
<flag name="xs">Build Perl modules with embedded C code for speed; requires rebuilds on Perl update</flag>
</use>
</pkgmetadata>
+47
View File
@@ -0,0 +1,47 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# Note: if your package uses the texi2dvi utility, it must depend on the
# virtual/texi2dvi package to pull in all the right deps. The tool is not
# usable out-of-the-box because it requires the large tex packages.
EAPI=6
inherit flag-o-matic toolchain-funcs
DESCRIPTION="The GNU info program and utilities"
HOMEPAGE="https://www.gnu.org/software/texinfo/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="nls static xs"
RDEPEND="
!=app-text/tetex-2*
>=sys-libs/ncurses-5.2-r2:0=
xs? ( dev-lang/perl:= )
!xs? ( dev-lang/perl )
dev-perl/libintl-perl
dev-perl/Unicode-EastAsianWidth
dev-perl/Text-Unidecode
nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
app-arch/xz-utils
nls? ( >=sys-devel/gettext-0.19.6 )"
src_configure() {
# Respect compiler and CPPFLAGS/CFLAGS/LDFLAGS for Perl extensions. #622576
local -x PERL_EXT_CC="$(tc-getCC)" PERL_EXT_CPPFLAGS="${CPPFLAGS}" PERL_EXT_CFLAGS="${CFLAGS}" PERL_EXT_LDFLAGS="${LDFLAGS}"
use static && append-ldflags -static
local myeconfargs=(
--with-external-libintl-perl
--with-external-Unicode-EastAsianWidth
--with-external-Text-Unidecode
$(use_enable nls)
$(use_enable xs perl-xs)
)
econf "${myeconfargs[@]}"
}