x11-wm/qtile: version bump to 0.13.0

Signed-off-by: Tim Harder <radhermit@gentoo.org>

x11-wm/qtile/Manifest

@@ -1,2 +1,3 @@
 DIST qtile-0.10.6.tar.gz 328892 BLAKE2B 3a4887808b87b0cbe4410d2bac8af4664873d2aa9b8c782f8c026ae78ba586b6e02d9a50ee42434afa916e9fe9041a7a15a68f9026ee7d95a0edec2594515cfa SHA512 39eef26358e1220ca766b030733396206df68677e3f23d6847d375f479952a4e2d47e0c3e59fab2e5046e899bad91d107a913bb25458fb66859dec3fa8c0e956
 DIST qtile-0.12.0.tar.gz 447139 BLAKE2B c1bea9ba8b36ccf14b7e55b4a2cbc05714ecffef33d992e9bf1683e6f8c416d481cf9d141bbf0fe62df65aeb3555290647d072dd45f507b08e0d523f992a1671 SHA512 a94237c40775524e16aebdd8555d0ed0623c248b65aee32851145e8a6cc54ce4d46ee5cf4c4f583e468de4557a565c4281660219e4b2ee1b73fb483567e1a5b2
+DIST qtile-0.13.0.tar.gz 468271 BLAKE2B e5e95b5bc56a06469e903f025946e6d0ea7b36501d017dd1470950c04a3ae1b35ec56b2a3c12f52daee75ae7b009c26285f49c0fa1ec5dda4993b2cf2da8a40c SHA512 06e6b32952c77c6b44872d5a52e0d196d5bb23c38da5d8acc2bba571f4d5fbadd8a7311f47e9301fb72a45c92b0255a90911edd12442392206da311fb7ada286

x11-wm/qtile/qtile-0.13.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+
+inherit distutils-r1 virtualx
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/qtile/qtile.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/qtile/qtile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
+HOMEPAGE="http://qtile.org/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+# docs require sphinxcontrib-blockdiag and sphinxcontrib-seqdiag
+
+RDEPEND="
+	x11-libs/cairo[xcb]
+	x11-libs/pango
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cairocffi-0.7[${PYTHON_USEDEP}]
+	>=dev-python/cffi-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	>=dev-python/xcffib-0.5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/trollius[${PYTHON_USEDEP}]' 'python2*')
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/xvfbwrapper[${PYTHON_USEDEP}]
+		x11-base/xorg-server[xephyr]
+		x11-apps/xeyes
+		x11-apps/xcalc
+		x11-apps/xclock
+	)
+"
+
+# display retry backoff slowness and failures
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.12.0-tests.patch )
+
+python_test() {
+	# force usage of built module
+	rm -rf "${S}"/libqtile || die
+	PYTHONPATH="${BUILD_DIR}/lib" py.test -v "${S}"/test || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGELOG README.rst )
+	distutils-r1_python_install_all
+
+	insinto /usr/share/xsessions
+	doins resources/qtile.desktop
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/${PN}-session ${PN}
+}

x11-wm/qtile/qtile-9999.ebuild

@@ -1,8 +1,8 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
 
 inherit distutils-r1 virtualx
 
@@ -44,7 +44,7 @@ DEPEND="${RDEPEND}
 	)
 "
 
-# display retry backoff slowness and failures 
+# display retry backoff slowness and failures
 RESTRICT="test"
 
 PATCHES=( "${FILESDIR}"/${PN}-0.12.0-tests.patch )