dev-lang/orc: bump to 0.4.28

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-lang/orc/Manifest

@@ -1 +1,2 @@
 DIST orc-0.4.27.tar.xz 465116 BLAKE2B 1289867c84371797350847e1ae71a002ec250abc56611fe6ec8d263ff64e17ed8d990f45adfbf6d1a0c7e98c2e6ec30c3135e433f00e9fa53cecce359f5b2d72 SHA512 5ca0b4553e370ea7c95acfc8248d9d568dafc9577041d47f52c7d0945456c534e18e0e80d28df9301d6deac1ea4f8ea6a51ca373b32927c8724846d8ec1f73e8
+DIST orc-0.4.28.tar.xz 469460 BLAKE2B 86fa2d10a33fbffbb2b96827adbddaa81d0baa8135fe21fba338cbcd25a1c1e853873ec1c4ef5c0a32d66ba95f855f1f16ddbc32f68a89e5a98c75b9b0261aa7 SHA512 2ae3100e7d0c03eba9a8a10a8924da4d729e1967b63e5dfdf88c4aee907d7ece82c782d74f4cb7e28a366dd74ce5e1ddc6e2b971e5a2f879b0501cc313b93410

dev-lang/orc/orc-0.4.28.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic multilib-minimal pax-utils
+
+DESCRIPTION="The Oil Runtime Compiler, a just-in-time compiler for array operations"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="BSD BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples pax_kernel static-libs test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=dev-util/gtk-doc-am-1.12
+"
+
+src_prepare() {
+	default
+
+	# Do not build examples	
+	sed -e '/SUBDIRS/ s:examples::' \
+		-i Makefile.am Makefile.in || die
+}
+
+multilib_src_configure() {
+	# any optimisation on PPC/Darwin yields in a complaint from the assembler
+	# Parameter error: r0 not allowed for parameter %lu (code as 0 not r0)
+	# the same for Intel/Darwin, although the error message there is different
+	# but along the same lines
+	[[ ${CHOST} == *-darwin* ]] && filter-flags -O*
+
+	# FIXME: handle backends per arch? What about cross-compiling for the other arches?
+	ECONF_SOURCE="${S}" econf \
+		--disable-gtk-doc \
+		--enable-backend=all \
+		$(use_enable static-libs static) \
+		$(use_enable test tests)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files --all
+
+	if use pax_kernel; then
+		pax-mark m "${ED}"usr/bin/orc-bugreport
+		pax-mark m "${ED}"usr/bin/orcc
+		pax-mark m "${ED}"usr/$(get_libdir)/liborc*.so*
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/{*.c,*.orc}
+	fi
+}
+
+pkg_postinst() {
+	if use pax_kernel; then
+		ewarn "Please run \"revdep-pax\" after installation".
+		ewarn "It's provided by sys-apps/elfix."
+	fi
+}