gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/astroid: Bump to 3.3.11

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2025-07-13 21:11:34 +02:00
parent fb0fa9f388
commit d68c592cf1
2 changed files with 73 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/astroid/Manifest
View File

@@ -1 +1,2 @@
DIST astroid-3.3.10.gh.tar.gz 467911 BLAKE2B da2e62ff056298bd0dc7aed3a9ab5af25968a2343a5339d409a2d03f0043cbe6024e1440332c797f3645db4b836f54b1a7ea2dbd09f3d49ee765a19d0bd0d15c SHA512 bec58f47f26a56f3700a6f10add2b90c018a2127b35036e1e4fc1d6c41fb35b67362195c506affba9ddf8ea120993e17adb562b799f1ee45622c79def4547e84
DIST astroid-3.3.11.gh.tar.gz 469464 BLAKE2B cb2ad429fa303e1049de685079d814696f9a907f75d85e0eb6aadef34d791ca2564e2727aff604e1f15b8bdd262b6c5dbfaa64193bac008d39e9bb7e642254cc SHA512 7dd0fae9fa6135abb505af567731f9062ea5f45b5c2e9c613fd1c5cbeeb409779a620cde3ecc42cd8a0733ccebc58b5e8e66baa1a38b6f46b1d3fcf2e33914b5

72
dev-python/astroid/astroid-3.3.11.ebuild Normal file
View File

@@ -0,0 +1,72 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
inherit distutils-r1
DESCRIPTION="Abstract Syntax Tree for logilab packages"
HOMEPAGE="
https://github.com/pylint-dev/astroid/
https://pypi.org/project/astroid/
"
SRC_URI="
https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
# dev-python/regex isn't available for pypy
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-python/attrs[${PYTHON_USEDEP}]
>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
dev-python/python-dateutil[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/regex[${PYTHON_USEDEP}]
' 'python*')
)
"
EPYTEST_PLUGINS=()
distutils_enable_tests pytest
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
python_test() {
local EPYTEST_IGNORE=()
local EPYTEST_DESELECT=(
# hangs
tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
# no clue why they're broken
tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
# TODO
tests/test_builder.py::BuilderTest::test_data_build_error_filename
# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
# old pythons only
tests/brain/test_dataclasses.py::test_pydantic_field
tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
)
if ! has_version "dev-python/mypy[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=(
tests/test_raw_building.py
)
fi
epytest
}