gnome-base/gnome-panel: Version bump to 3.50.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/33016 Signed-off-by: Florian Schmaus <flow@gentoo.org>
2026-11-07 18:07:08 -08:00 · 2023-09-27 08:58:15 +02:00
parent 65bdc5209b
commit d641572f46
2 changed files with 80 additions and 0 deletions
@@ -1 +1,2 @@
 DIST gnome-panel-3.46.0.tar.xz 2797164 BLAKE2B 48f4a070df7015a8cca2b5041329f3ebb88474abf42cd21f74514ef557426c260110916eb1e23fafec1f99ec2e339258241484a87a6cd52a293d7df6abfff001 SHA512 a49f3978bd9561973c41083006b831cf4fcb07408048106ef56dae7e0809fb3ec825c8b4a1c09e818255c7995c45a6d33aa4f47e61f778f4b1f29ccc7c9033f7
+DIST gnome-panel-3.50.0.tar.xz 2769200 BLAKE2B a386ccf11408772939af434d9f69c00a3bc22c0c104acd2e88e105c3f0d8ea3cfcd9145e6fc5d6e802d02740bcc89a86af403a9ade86271eddb7d8325fecadad SHA512 29e5eb22feec1b2d57fc0cd4c307012bbad50b15d49dc0fc7e2c0a1090a744ca9f1857ee74f2f0a7f77943ebe6ecf4f71c577adaeb19633f34ba93aad26e3c74
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2 toolchain-funcs
+
+DESCRIPTION="The GNOME Flashback Panel"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-panel/"
+
+LICENSE="GPL-2+ FDL-1.1 LGPL-2.1+"
+SLOT="0"
+IUSE="eds elogind systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=gnome-base/gnome-desktop-2.91.0:3=
+	>=x11-libs/gdk-pixbuf-2.26.0:2
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.67.1:2
+	>=x11-libs/gtk+-3.22.0:3[X]
+	>=x11-libs/libwnck-43.0:3
+	>=gnome-base/gnome-menus-3.7.90:3
+	eds? ( >=gnome-extra/evolution-data-server-3.46.0:= )
+	elogind? ( >=sys-auth/elogind-230 )
+	systemd? ( >=sys-apps/systemd-230:= )
+	>=x11-libs/cairo-1.0.0[X,glib]
+	>=dev-libs/libgweather-4.2.0:4=
+	>=gnome-base/dconf-0.13.4
+	>=x11-libs/libXrandr-1.3.0
+	gnome-base/gdm
+	x11-libs/libX11
+	x11-libs/libXi
+	sci-geosciences/geocode-glib:2
+	sys-auth/polkit
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+" # yelp-tools and autoconf-archive for eautoreconf
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		$(use_enable eds)
+	)
+
+	# Below elogind MENU_* pkg-config calls need to match up with what upstream has
+	# each version (libsystemd replaced with libelogind). Explicit per-version die
+	# to force a manual recheck. Only update the explicit version if the
+	# "PKG_CHECK_MODULES([MENU], ...)" block did not change; otherwise adjust
+	# elogind conditional block below accordingly first.
+	# DO NOT just change the version, look in configure.ac in which PKG_CHECK_MODULES-sections
+	# libsystemd is used and check if there are new sections where it is used!
+	if ver_test ${PV} -ne 3.50.0; then
+		die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
+	fi
+
+	if use elogind; then
+		local pkgconfig="$(tc-getPKG_CONFIG)"
+		myconf+=(
+			ACTION_BUTTON_CFLAGS="$(${pkgconfig} --cflags gio-unix-2.0 gtk+-3.0 libelogind x11)"
+			ACTION_BUTTON_LIBS="$(${pkgconfig} --libs gio-unix-2.0 gtk+-3.0 libelogind x11)"
+			LAUNCHER_CFLAGS="$(${pkgconfig} --cflags gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+			LAUNCHER_LIBS="$(${pkgconfig} --libs gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+			MENU_CFLAGS="$(${pkgconfig} --cflags gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+			MENU_LIBS="$(${pkgconfig} --libs gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+		)
+	fi
+
+	gnome2_src_configure "${myconf[@]}"
+}