dev-python/python-ldap: Bump to 3.4.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-ldap/Manifest

@@ -1 +1,2 @@
 DIST python-ldap-3.4.0_p20220420.tar.gz 377780 BLAKE2B 433178138587dc09bfe1e6a8e894c001baf6e07c76266ca9d7c56b279f9e9ca5a642528a5869a837a9ee5576a2cf17afdeea313b4a8bc930926397738d6a5daf SHA512 0dfe8ff4737a630a08c7cd4d94f30c78fd1e0558ffc0609439d95ef064b72aef9d4ec4cdc0d40aaf1fc46396bdc0cbbdf0bf3cf6bb5e94bf8a9e3083b9ba1bf4
+DIST python-ldap-3.4.2.gh.tar.gz 377981 BLAKE2B 6efa768dd035f8867abacfd9cc1b9ceca1a468c79550d2529130bd8eaf7546e4474d5798cf9090a9a74f05286ca30a33b8e54821292b8aa2e27358f93d72cb7b SHA512 3a68dd2c160d7d74061d9c9eb060be6faeec1f607f3853722f969d7d1dc76c7da160aa20a4c139feb4d2eba6dbf2e2cfb02551cabd6fbf413654f32f73e94c15

dev-python/python-ldap/python-ldap-3.4.2.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Various LDAP-related Python modules"
+HOMEPAGE="
+	https://www.python-ldap.org/en/latest/
+	https://pypi.org/project/python-ldap/
+	https://github.com/python-ldap/python-ldap/
+"
+SRC_URI="
+	https://github.com/python-ldap/python-ldap/archive/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x86-solaris"
+IUSE="examples sasl ssl"
+
+RDEPEND="
+	>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
+	net-nds/openldap:=[sasl?,ssl?]
+"
+# We do not link against cyrus-sasl but we use some
+# of its headers during the build.
+DEPEND="
+	net-nds/openldap:=[sasl?,ssl?]
+	sasl? ( >=dev-libs/cyrus-sasl-2.1 )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx Doc
+
+python_prepare_all() {
+	if ! use sasl; then
+		sed -i 's/HAVE_SASL//g' setup.cfg || die
+	fi
+	if ! use ssl; then
+		sed -i 's/HAVE_TLS//g' setup.cfg || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Run all tests which don't require slapd
+	local EPYTEST_IGNORE=(
+		t_bind.py
+		t_cext.py
+		t_edit.py
+		t_ldapobject.py
+		t_ldap_options.py
+		t_ldap_sasl.py
+		t_ldap_schema_subentry.py
+		t_ldap_syncrepl.py
+		t_slapdobject.py
+	)
+	pushd Tests >/dev/null || die
+	epytest
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r Demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}