xfce-base/libxfce4ui: Bump to 4.15.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4ui/Manifest

@@ -1,2 +1,3 @@
 DIST libxfce4ui-4.14.1.tar.bz2 756175 BLAKE2B d487cc0a04b6053ead6670eeb83cafe1c4098818d5ad6a94a81176720d78cfd65160156961cbb526baa1640ae66a5c6958f707b7078c412d81fcd24cc8cf4013 SHA512 f42f41da3a683a0c56c3b1e7ba420c4f50909d2613e681d053b09b50bc0eb7f750f44c892e94b0ee8b9207983a87c0cadbda1ad93d0df74ae351dc8812025407
 DIST libxfce4ui-4.15.1.tar.bz2 720332 BLAKE2B 198a162c2dd47d83102da8aee0c7943c869d708e36f2e0806988f63fb1f88c84c0b9ee3b5a6b14279a5359fa2afc1dfe7f8faedaff281635e0a2299a3a06618c SHA512 1b46109b79b849b38de7e8ebf0958ab5edace48cfc0a8b58c07d29d5f9b73998e078f6aa27650c0b30898cad5c251cdc45303e13982c1bb72101f9bc13d72f10
+DIST libxfce4ui-4.15.2.tar.bz2 740189 BLAKE2B 77263318afe376a9b50f129c6969fcb540685bb151f78a94f0024e27871cd8fb895d3edc41483ff8f3b8c8c28d24142252155c6ca68b614375c1fc93f08fdb45 SHA512 1ac2dea2200f00846bc5b5f86d02292f345dc904a121df86a662ca1844b1bdd9eea6bf0cd88dda97ff84e30d990b065bd9597cb563dbb75f639e820d41f83dbc

xfce-base/libxfce4ui/libxfce4ui-4.15.2.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade introspection libgtop startup-notification vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.42:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.12:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libgtop? ( gnome-base/libgtop )
+	startup-notification? ( x11-libs/startup-notification )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable libgtop glibtop)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}