sci-astronomy/kstars: add 3.6.7

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-09 18:47:16 -08:00 · 2023-10-01 12:46:53 +02:00
parent 7297794355
commit d5f6acfecb
2 changed files with 108 additions and 0 deletions
@@ -1 +1,2 @@
 DIST kstars-3.6.6.tar.xz 135870036 BLAKE2B 20a313b4df8c266cf406677ed062b8788b1840670c88c86043a84ef15947f16247d0733f2b91b623a951e53659fcd6e3bbd25b22c105a3ac3df3481fe57078a3 SHA512 ef2cbd12578cc336e46dda875e8d6b077922c9732b4afb35b7782ae1573c2a6ccd0337d1ba1206d2e5ac5922f8b9c91ddc45f59b6a487f22b779f8d1100b1636
+DIST kstars-3.6.7.tar.xz 138532496 BLAKE2B 173cea5d81b72a181dd7c17ea8159d739675fe60bfab3fb9ccd0a47b32a7f2e2231d5eaa26074eb6d2479b1f62a3c5236494763d82370d844dfaebbc14adc3a0 SHA512 bfefad8c3cd55a2b01e8be240ede7c2ea7cadf99d44c9558e56ac0b0d890c96c3392a6de4c062341f3aff994fc7e95b79a69454a436bc8bce760942cd42f80cd
@@ -0,0 +1,107 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Desktop Planetarium"
+HOMEPAGE="https://apps.kde.org/kstars/ https://edu.kde.org/kstars/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="5"
+IUSE="fits indi +password raw wcs"
+
+REQUIRED_USE="indi? ( fits ) ${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdatavis3d-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebsockets-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sci-libs/gsl:=
+	sys-libs/zlib
+	fits? ( sci-libs/cfitsio:= )
+	indi? (
+		>=sci-libs/indilib-2.0.2
+		sci-libs/libnova:=
+		>=sci-libs/stellarsolver-2.2
+	)
+	password? ( dev-libs/qtkeychain:=[qt5(+)] )
+	raw? ( media-libs/libraw:= )
+	wcs? ( sci-astronomy/wcslib:= )
+"
+# TODO: Add back when re-enabled by upstream
+# 	opengl? (
+# 		>=dev-qt/qtopengl-${QTMIN}:5
+# 		virtual/opengl
+# 	)
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:3
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PYKSTARS=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_LibXISF=ON # not packaged
+		-DBUILD_DOC=$(usex handbook)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package indi INDI)
+		$(cmake_use_find_package indi Nova)
+		$(cmake_use_find_package password Qt5Keychain)
+		$(cmake_use_find_package raw LibRaw)
+		$(cmake_use_find_package wcs WCSLIB)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 842768, test declared unstable by upstream
+	local myctestargs=(
+		-E "(TestKSPaths)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Display 'current' pictures of planets" x11-misc/xplanet
+	fi
+	ecm_pkg_postinst
+}