x11-misc/dunst: add 1.9.1

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Conrad Kostecki
2023-03-12 19:59:56 +01:00
parent c5695008b7
commit d5d6b0f83c
2 changed files with 84 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST dunst-1.9.0.tar.gz 4609222 BLAKE2B 4879122e342c1e518bca079bacd4ae769fd7da41db681230613c61531e62df94223757372c428c06710afd843200dcb78883d352f4e25098f0672b5c89ab0d87 SHA512 e43c960561d1f804c1d8f73f9376b33f61bf1ba5c5d0579c9875ef96da6522e214d5b74166ca3375dff1b4b0291b611b2d9ac1fb41fa8722db04c21e898824d1
DIST dunst-1.9.1.tar.gz 4614410 BLAKE2B f2d3b5ca28ac74461e31c09f7c5f8369dd6d05e8133d184625344b5445fac8e673cf5c57d44ea8bf0f3d320167663529ea49e8de0ed873afae327cb7db55d5ff SHA512 6045529196c2d8bd89d2976db9712bf15ec75923fdab414870e1ae2af2eb87afc2b5886cb707a19ea113ec746f90fde1e52631eec9b7a96f1af03acbe6445f32
+83
View File
@@ -0,0 +1,83 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit systemd toolchain-funcs
DESCRIPTION="Lightweight replacement for common notification daemons"
HOMEPAGE="https://dunst-project.org/ https://github.com/dunst-project/dunst"
SRC_URI="https://github.com/dunst-project/dunst/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
IUSE="wayland"
DEPEND="
dev-libs/glib:2
sys-apps/dbus
x11-libs/cairo[X,glib]
x11-libs/gdk-pixbuf:2
x11-libs/libX11
x11-libs/libXext
x11-libs/libXScrnSaver
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libnotify
x11-libs/pango[X]
x11-misc/xdg-utils
wayland? ( dev-libs/wayland )
"
RDEPEND="${DEPEND}"
BDEPEND="
dev-lang/perl
virtual/pkgconfig
wayland? ( dev-libs/wayland-protocols )
"
src_prepare() {
default
# Respect users CFLAGS
sed -e 's/-Os//' -i config.mk || die
# Use correct path for dbus and system unit
sed -e "s|##PREFIX##|${EPREFIX}/usr|" -i dunst.systemd.service.in || die
sed -e "s|##PREFIX##|${EPREFIX}/usr|" -i org.knopwob.dunst.service.in || die
}
src_configure() {
tc-export CC PKG_CONFIG
default
}
src_compile() {
local myemakeargs=(
SYSCONFDIR="${EPREFIX}/etc/xdg"
SYSTEMD="0"
WAYLAND="$(usex wayland 1 0)"
)
emake "${myemakeargs[@]}"
}
src_install() {
local myemakeargs=(
PREFIX="${ED}/usr"
SYSCONFDIR="${ED}/etc/xdg"
SYSTEMD="0"
WAYLAND="$(usex wayland 1 0)"
)
emake "${myemakeargs[@]}" install
insinto /usr/share/zsh/site-functions
newins contrib/_dunst.zshcomp _dunst
newins contrib/_dunstctl.zshcomp _dunstctl
systemd_newuserunit dunst.systemd.service.in dunst.service
}