gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-17 14:49:30 -07:00
Code Issues Projects Releases Wiki Activity

dev-embedded/esptool: add 4.12.0

Browse Source 
Signed-off-by: Martin Dummer <martin.dummer@gmx.net>
Part-of: https://github.com/gentoo/gentoo/pull/46608
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Martin Dummer
2026-07-24 15:48:05 +02:00
committed by Viorel Munteanu
parent 0becfcebee
commit d57d3c50e8
2 changed files with 67 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-embedded/esptool/Manifest
View File

@@ -1,3 +1,4 @@
DIST esptool-4.10.0.tar.gz 5961194 BLAKE2B 153d57ec90dee53a237dcdf694e6add85d380421a30a4d2ff7c13f73a6511fb120d2a6071adc7327e6ce3cb82c496bd33c972a5739b6d565369e60453be73238 SHA512 98a5329d50286766a11c86b371cb4c383a9fa6de87dbdbc97afc8def63a9f6aba7b633467fb896ba93638006ac73cb1a243973b7daddbc7959e0988d0c00eb6d
DIST esptool-4.12.0.tar.gz 6013292 BLAKE2B 49a6abc7fd6fec84ba3ec08087f7fbf6a27f2adf16fc6b1dffef8ece09b04f84bf128ecbece1cc0f2fde819bb5033d856c282fee40dcd5791bc5054302c28954 SHA512 af8ccb2abdbb0671ff475e61070dd2e18ea676391449ea1333aa60377b5267bb11297d71319dba32712006a7dbeccdebbdea3cd178a670a0e90d2ba7b0481322
DIST esptool-5.2.0.tar.gz 6056496 BLAKE2B cc036196b9a8a84f9f44c5d5f44796d531510f967946c984f6b5c74c1bd8558ffd611f3f59fce9bcde3d7ab5f161e6ef4bc5520804ebec774bfcc60d61051f67 SHA512 df62952b12abb9d47a7f5a46ea00ce1bd59f32c73017e6b13f31eb2d197caec17810ff358e4a538ed9be958000de88bc97c5c74c41c06f9340e784aec5b6f7e6
DIST esptool-5.3.0.tar.gz 6106512 BLAKE2B bf831cc2b91675dc0bf83eb2042ad86bcfbe36d8fbd8c39c4c855413b157283d31c77b6c84ab4cc262d688cbbe77da109977e5213e32d5d9d05eb7c6aeac8be0 SHA512 b7c357c73f0fe7c24636bdf0752ec4fb9352a2e2fe5021e62d716f6fdee09e5e49780901275dcba7c408d7ebcfe03a4fa8c6b8ca0bf2376988788cc2756e8bbb

66
dev-embedded/esptool/esptool-4.12.0.ebuild Normal file
View File

@@ -0,0 +1,66 @@
# Copyright 2021-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{12..14} )
DISTUTILS_USE_PEP517=setuptools
DISTUTILS_SINGLE_IMPL=1
inherit distutils-r1 eapi9-ver
DESCRIPTION="Utility to communicate with the ROM bootloader in Espressif ESP8266 and ESP32"
HOMEPAGE="https://github.com/espressif/esptool"
SRC_URI="https://github.com/espressif/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
RDEPEND="
$(python_gen_cond_dep '
dev-python/bitstring[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/ecdsa[${PYTHON_USEDEP}]
dev-python/intelhex[${PYTHON_USEDEP}]
dev-python/pyserial[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/reedsolo[${PYTHON_USEDEP}]
')
"
BDEPEND="
$(python_gen_cond_dep '
dev-python/wheel[${PYTHON_USEDEP}]
')
test? ( $(python_gen_cond_dep '
dev-python/ecdsa[${PYTHON_USEDEP}]
dev-python/pyelftools[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
') )
"
EPYTEST_PLUGINS=( )
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# need real hardware connected
test/test_esptool.py
# need network
test/test_uf2_ids.py
)
src_prepare() {
default
# test_espsecure_hsm.py needs setup of a "Soft HSM" or real hardware. remove.
rm test/test_espsecure_hsm.py || die
}
pkg_postinst() {
if ver_replacing -lt 4; then
ewarn "${P} - new 4.x release with breaking changes:"
ewarn " - Public API has been defined by limiting access to internals that have been refactored into multiple source files"
ewarn " - If active security features are detected, the default behavior changes to prevent unintentional bricking"
ewarn " - Flash parameters in an image header can now be changed only when no SHA256 digest is appended"
ewarn " - The ESP8684 alias has been removed, ESP32-C2 has to be used"
ewarn " - Megabit flash sizes have been deprecated, use megabyte units from now on"
fi
}