dev-util/quilt: add 0.69

Signed-off-by: Mike Pagano <mpagano@gentoo.org>

dev-util/quilt/Manifest

@@ -1 +1,2 @@
 DIST quilt-0.68.tar.gz 551096 BLAKE2B b012d0ccc0efaa2b645eafe9279a511a9fbd7546f22f35aebdb5488bde433e841472b907cacdd5f451e20a15b348f651028591f9a2d5b195613948f754c06cb5 SHA512 a2a58b330ccb3dd55b1f280310d506c605166bceedf7439582cdf8a198ca4aa34a375fd8bfd4027c540481bcdf5e6175eafd19707aaabe194b01cf7caa40572e
+DIST quilt-0.69.tar.gz 553556 BLAKE2B cdbc3569291bac29306f8af622e277ec6b0bb3d5c1356e07bfb7c7998006f8339050225b2f520292a2c8a202a480060565c8d1c035b3935f4a7f99eb99c2136f SHA512 b9611ec85da6aebfb51c64923c5f0636fb7207c54921619b4f0796388fe566d7ab8b7058189f0b3157fca06314ce183206ddc1faaaa72f2bdddd8eeddb7834e9

dev-util/quilt/quilt-0.69.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit bash-completion-r1 elisp-common
+
+DESCRIPTION="quilt patch manager"
+HOMEPAGE="https://savannah.nongnu.org/projects/quilt"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-1+"  # any GPL version for quilt.el
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-solaris"
+IUSE="emacs graphviz"
+# unresolved test failures
+RESTRICT="test"
+
+RDEPEND="sys-apps/ed
+	dev-util/diffstat
+	graphviz? ( media-gfx/graphviz )
+	elibc_Darwin? ( app-misc/getopt )
+	elibc_SunOS? ( app-misc/getopt )
+	sys-apps/coreutils
+	app-arch/zstd:="
+
+PATCHES=( "${FILESDIR}"/${PN}-el-0.45.4-header-window.patch )
+
+pkg_setup() {
+	use graphviz && return 0
+	echo
+	elog "If you intend to use the folding functionality (graphical illustration of the"
+	elog "patch stack) then you'll need to remerge this package with USE=graphviz."
+	echo
+}
+
+src_prepare() {
+	# Add support for USE=graphviz
+	use graphviz || PATCHES+=( "${FILESDIR}"/${PN}-0.66-no-graphviz.patch )
+	default
+}
+
+src_configure() {
+	local myconf=()
+	[[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] \
+		&& myconf+=( "--with-getopt=${EPREFIX}/usr/bin/getopt-long" )
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	default
+	use emacs && elisp-compile lib/quilt.el
+}
+
+src_install() {
+	emake BUILD_ROOT="${D}" install
+
+	rm -rf "${ED}"/usr/share/doc/${P}
+	dodoc AUTHORS COPYING NEWS TODO "doc/README" "doc/README.MAIL" "doc/quilt.pdf"
+
+	# Remove misplaced Emacs mode
+	rm -rf "${ED}"/usr/share/emacs || die
+
+	if use emacs; then
+		elisp-install ${PN} lib/quilt.{el,elc}
+		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
+		dodoc doc/README.EMACS
+	fi
+
+	rm -rf "${ED}"/etc/bash_completion.d
+	newbashcomp bash_completion ${PN}
+
+	# Remove the compat symlinks
+	rm -rf "${ED}"/usr/share/quilt/compat
+}