media-libs/aubio: Bump to version 0.4.9

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
2019-02-14 03:58:43 +01:00
parent 2cde2c1a6a
commit d4dcf8d942
3 changed files with 147 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST aubio-0.4.7.tar.bz2 372173 BLAKE2B 544239b215dd87d4cf4a6ed6b5dd856411d0a3f1c3242e3e1077fa0780160785a9934884a1f0d0dc80fe21b1d417bc3800db59842ec300a4c29d75b7942cba05 SHA512 30c614f2b502b993df28d4746a99421fe0aada33c98c42ea19c271554b29b360cb4d4f6650c1b1da508da4bc341348c5944cb452f69b2bf354ca6348f84de260
DIST aubio-0.4.8.tar.bz2 387933 BLAKE2B e30d0ce97360376edf8eba895dc3040157a139c843ef9d6bf0483ffb750916eaccf9e28b8d80dcc0034572cca4f08479e4db44468c96206ce7b60a2fa9600634 SHA512 e58b32beda36865a5243ec7ed4647cf96e3652a25fd319fc697c08f93487f895070dc66b830700b40b879220c2e3a53b8cdc255ce2e34770ba5e34b36a4f51b4
DIST aubio-0.4.9.tar.bz2 397604 BLAKE2B b849d92678ea8fb20e17921b1a61fdc85a84d4a528acfefa3278169ab5f7fe935217ec37dd9f931202f0f0a1fd3a9518372afbce34cc2dd3ca30c6b4e5d9a301 SHA512 0cb81bb4b15051db3f3f4d160d500af56fdfb237e0a74e3f366f53c2870030aa0a7cee8469a611a9694c36b8866d3d42ffb48241c999de08f3fee43e6d903130
+126
View File
@@ -0,0 +1,126 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
PYTHON_REQ_USE='threads(+)'
inherit distutils-r1 waf-utils
DESCRIPTION="Library for audio labelling"
HOMEPAGE="https://aubio.org/"
SRC_URI="https://aubio.org/pub/${P}.tar.bz2"
LICENSE="GPL-3"
SLOT="0/5"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc double-precision examples ffmpeg fftw jack libav libsamplerate sndfile python test"
RDEPEND="
ffmpeg? (
!libav? ( >=media-video/ffmpeg-2.6:0= )
libav? ( >=media-video/libav-9:0= )
)
fftw? ( sci-libs/fftw:3.0= )
jack? ( virtual/jack )
libsamplerate? ( media-libs/libsamplerate )
python? (
${PYTHON_DEPS}
dev-python/numpy[${PYTHON_USEDEP}]
)
sndfile? ( media-libs/libsndfile )
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
app-text/txt2man
virtual/pkgconfig
doc? ( app-doc/doxygen )
"
REQUIRED_USE="${PYTHON_REQUIRED_USE}
?? ( double-precision libsamplerate )
"
DOCS=( AUTHORS ChangeLog README.md )
PYTHON_SRC_DIR="${S}"
PATCHES=(
"${FILESDIR}"/${PN}-0.4.9-docdir.patch
)
src_prepare() {
default
sed -e "s:doxygen:doxygen_disabled:" -i wscript || die
if ! use test; then
sed -e "/bld.*tests/d" -i wscript || die
fi
}
src_configure() {
python_setup
local mywafconfargs=(
--enable-complex
--docdir="${EPREFIX}"/usr/share/doc/${PF}
$(use_enable double-precision double)
$(use_enable fftw fftw3)
$(use_enable ffmpeg avcodec)
$(use_enable jack)
$(use_enable libsamplerate samplerate)
$(use_enable sndfile)
)
use double-precision || mywafconfargs+=( $(use_enable fftw fftw3f) )
waf-utils_src_configure "${mywafconfargs[@]}"
if use python ; then
cd "${PYTHON_SRC_DIR}" || die
distutils-r1_src_configure
fi
}
src_compile() {
waf-utils_src_compile --notests
if use doc; then
cd "${S}"/doc || die
emake dirhtml
fi
if use python ; then
cd "${PYTHON_SRC_DIR}" || die
distutils-r1_src_compile
fi
}
src_test() {
waf-utils_src_compile --alltests
if use python ; then
cd "${PYTHON_SRC_DIR}" || die
distutils-r1_src_test
fi
}
src_install() {
waf-utils_src_install
if use examples; then
# install dist_noinst_SCRIPTS from Makefile.am
dodoc -r examples
fi
if use python ; then
cd "${PYTHON_SRC_DIR}" || die
DOCS="" distutils-r1_src_install
newdoc python/README.md README.python
fi
if use doc; then
dodoc doc/*.txt
docinto html
dodoc -r doc/_build/dirhtml/.
fi
find "${ED}" -name "*.a" -delete || die
}
@@ -0,0 +1,20 @@
--- aubio-0.4.9/wscript
+++ aubio-0.4.9/wscript
@@ -557,7 +557,7 @@
target = bld.path.find_or_declare('api/index.html'),
cwd = bld.path.find_dir('doc'))
# evaluate nodes lazily to prevent build directory traversal warnings
- bld.install_files('${DATAROOTDIR}/doc/libaubio-doc/api',
+ bld.install_files('${DATAROOTDIR}/doc/' + os.environ['PF'] + '/libaubio-doc/api',
bld.path.find_or_declare('api').ant_glob('**/*',
generator=True), cwd=bld.path.find_or_declare('api'),
relative_trick=True)
@@ -582,7 +582,7 @@
source = bld.path.find_dir('doc').ant_glob('*.rst'),
target = bld.path.find_or_declare('manual/index.html'))
# evaluate nodes lazily to prevent build directory traversal warnings
- bld.install_files('${DATAROOTDIR}/doc/libaubio-doc/manual',
+ bld.install_files('${DATAROOTDIR}/doc/' + os.environ['PF'] + '/libaubio-doc/manual',
bld.path.find_or_declare('manual').ant_glob('**/*',
generator=True), cwd=bld.path.find_or_declare('manual'),
relative_trick=True)