kde-frameworks/kidletime: 6.18.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/kidletime/Manifest

@@ -1,2 +1,3 @@
 DIST kidletime-6.16.0.tar.xz 30792 BLAKE2B e48df84c108092cd0aa7e7a1d4a03a1088254ab705887caeeb13ad1fc794a29f84a27695ce10c7bc6e999e3c1c1ec0f19cafd22658b8f05a4b4226501c66c319 SHA512 f7070626a066d5777704239401d6f5b8c0264ea2ba190f5aa34a1cc33c5452d2ab3d88a07c2d417995e26854b97cea9c954f42a48598326bfece071860bc6f3a
 DIST kidletime-6.17.0.tar.xz 30820 BLAKE2B 284924431c48c2fe2fda7378de4dd66bdd14915d57785bbd49855215f2dd9c1bc5295416b969974b4cc65847c4e5d2ff7d3d8e76ec366b98573921636aa9cf8e SHA512 404b625e0fa05b4afb6b15ca84a4e652d41e7a9d1d1b4d19fa5d86ae3ac9a9b7b36cd986deb7a679166664756f5809ae8b1e996db20c3055154c27ceaf8f54f7
+DIST kidletime-6.18.0.tar.xz 30808 BLAKE2B e902f044c53c1c90ac365040a6d3119f11b8db3a65f3abaf01c018beb05d026909e8aab5b749fc8090591089404e82d3fdf11286525392a77171e3a7ae99d228 SHA512 9ff90f2cb5546fd431a3aaa8209a61fe52fa7de9ee8ac935b7c3d8078781279c0c5d4550d79f035d878eace9e136b7a48dd456504f4dba6c8ded3116180973e2

kde-frameworks/kidletime/kidletime-6.18.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+RDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+BDEPEND="wayland? ( >=dev-qt/qtbase-${QTMIN}:6[wayland] )"
+BDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}