media-libs/openal: bump to 1.21.1

Bug: https://bugs.gentoo.org/739252
Closes: https://bugs.gentoo.org/764056
Closes: https://bugs.gentoo.org/738240
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

media-libs/openal/Manifest

@@ -1,2 +1,3 @@
 DIST openal-soft-1.20.1.tar.bz2 512971 BLAKE2B be0abb32698d5ea77e8667e1b00fb123673325b0361c711d6c232d96d1add6d5c9a3e2ba7a3d04afcad27fe4f18ae803f690b14c98d198b77c75f1865679081f SHA512 a8a03a2162b5d35e66adc079e81d7fa075b83a3ee1cec3412cb40f7789263ed8bd005beefb7ef995f464dfa43aac22ea0f547b752dfc7533ed9120a95fb92513
 DIST openal-soft-1.21.0.tar.bz2 525483 BLAKE2B 28d44cfddd93bf6637b476cdcc44c5f69a1a8036c17d63be2defdce47d038bf54c29c9248070a65e7c6f86497ed3b79fd5548832bd67a1ebb67ffc363e46de9b SHA512 12e7dca4040765e06658d2945e984af01f21c65b7d44f9daee3a55457c27bd050bf74665e91ebfefdac09739774ace3e7a4bfc02870778cd65268941314aeb3b
+DIST openal-soft-1.21.1.tar.bz2 524787 BLAKE2B ca052ee3ba18188a9b8342540b8a9ffa95a0c19c137f5e799fa69768d51ec30da55afa46bddf3d9b65e589b94423bc5b23f2090e07bb9fc2a34937f9c199ee89 SHA512 420eec18149a9b784daaabe8a2865de3b87d5550cf2e8e06569464d0b5ba6e51d904c18f1461af08676bf8c8b76ef270e860008d79545a5f85131299e89bffd4

media-libs/openal/openal-1.21.1.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+MY_P="${PN}-soft-${PV}"
+
+DESCRIPTION="A software implementation of the OpenAL 3D audio API"
+HOMEPAGE="https://www.openal-soft.org/"
+SRC_URI="https://www.openal-soft.org/openal-releases/${MY_P}.tar.bz2"
+
+# See https://github.com/kcat/openal-soft/blob/e0097c18b82d5da37248c4823fde48b6e0002cdd/BSD-3Clause
+# Some components are under BSD
+LICENSE="LGPL-2+ BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="
+	alsa coreaudio debug jack oss portaudio pulseaudio sdl qt5
+	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
+	cpu_flags_arm_neon
+"
+
+RDEPEND="
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	portaudio? ( >=media-libs/portaudio-19_pre20111121-r1[${MULTILIB_USEDEP}] )
+	pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )
+
+src_configure() {
+	# -DEXAMPLES=OFF to avoid FFmpeg dependency wrt #481670
+	my_configure() {
+		local mycmakeargs=(
+			-DALSOFT_REQUIRE_ALSA=$(usex alsa)
+			-DALSOFT_REQUIRE_COREAUDIO=$(usex coreaudio)
+			-DALSOFT_REQUIRE_JACK=$(usex jack)
+			-DALSOFT_REQUIRE_OSS=$(usex oss)
+			-DALSOFT_REQUIRE_PORTAUDIO=$(usex portaudio)
+			-DALSOFT_REQUIRE_PULSEAUDIO=$(usex pulseaudio)
+			-DALSOFT_REQUIRE_SDL2=$(usex sdl)
+			-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
+			-DALSOFT_NO_CONFIG_UTIL=$(usex qt5 "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
+			-DALSOFT_EXAMPLES=OFF
+		)
+
+		# Avoid unused variable warnings, bug #738240
+		if use amd64 || use x86 ; then
+			mycmakeargs+=(
+				-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
+				-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
+				-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+			)
+		fi
+
+		if use arm || use arm64 ; then
+			mycmakeargs+=(
+				-DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon)
+			)
+		fi
+
+		cmake_src_configure
+	}
+
+	multilib_parallel_foreach_abi my_configure
+}