app-emulation/containers-storage: Bump to version 1.20.2

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-emulation/containers-storage/Manifest

@@ -1 +1,2 @@
 DIST containers-storage-1.18.1.tar.gz 3803605 BLAKE2B 6ecf7a2ac395f0973f2d071d6736ccd6dfe8917168b50daeb26b141457d9fc53d9f4471577c659dcf77f2d4058d0a5cecbe1599a365d7ae102916188dc44aa5d SHA512 1b2d16ae5703af232c58eb4ecc65b98a7f754cd9784b563e5323ef3303dc8f72896453f2fd84fee20490b72f9c2455437d5879f6c5c23aaa188316cb1b272211
+DIST containers-storage-1.20.2.tar.gz 3827404 BLAKE2B 7284a86c34c91c21e49d7c9f89bfe8cc65d3a6673d37ea2e6e769c8abda581189b62119480bfcb0757cc3b4b47e29c7e0c65d245ec9bac082674f4b29f0899e1 SHA512 6ed73080da5c284eb421dd3c192662b16b2c72801bd0043f676c1e3bf44ee9899b10dea7fe5e2e52f95ecc511606aa2d971fd064b4cc7c993459ea75bf14536f

app-emulation/containers-storage/containers-storage-1.20.2.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+SRC_URI="https://github.com/containers/storage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+	default
+
+	sed -e 's|: install\.tools|:|' -i Makefile || die
+
+	[[ -f hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		"hack/btrfs_tag.sh" || die; }
+
+	[[ -f hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+	export -n GOCACHE GOPATH XDG_CACHE_HOME #678856
+	emake GOMD2MAN=go-md2man FFJSON= containers-storage docs
+}
+
+src_install() {
+	dobin "${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	env -u GOFLAGS unshare -m emake local-test-unit || die
+}