sci-libs/onnx: install python modules

Closes: https://bugs.gentoo.org/915843
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

sci-libs/onnx/onnx-1.14.0-r1.ebuild

@@ -1,32 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{9..11} )
-inherit python-any-r1 cmake
-
-DESCRIPTION="Open Neural Network Exchange (ONNX)"
-HOMEPAGE="https://github.com/onnx/onnx"
-SRC_URI="https://github.com/onnx/${PN}/archive/refs/tags/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~riscv"
-RESTRICT="test"
-
-DEPEND=""
-RDEPEND="${DEPEND}
-	dev-libs/protobuf:="
-BDEPEND="
-	${PYTHON_DEPS}
-"
-
-PATCHES=( "${FILESDIR}"/${P}-cxx_14.patch )
-
-src_configure() {
-	local mycmakeargs=(
-		-DONNX_USE_PROTOBUF_SHARED_LIBS=ON
-	)
-	cmake_src_configure
-}

sci-libs/onnx/onnx-1.14.0-r2.ebuild

@@ -0,0 +1,59 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_OPTIONAL=1
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 cmake
+
+DESCRIPTION="Open Neural Network Exchange (ONNX)"
+HOMEPAGE="https://github.com/onnx/onnx"
+SRC_URI="https://github.com/onnx/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="python"
+RESTRICT="test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	python? (
+		${PYTHON_DEPS}
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+	)
+	dev-libs/protobuf:=
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="python? (
+	${DISTUTILS_DEPS}
+)"
+
+PATCHES=( "${FILESDIR}"/${P}-cxx_14.patch )
+
+src_prepare() {
+	cmake_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DONNX_USE_PROTOBUF_SHARED_LIBS=ON
+	)
+	cmake_src_configure
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use python && distutils-r1_src_compile
+}
+
+src_install() {
+	cmake_src_install
+	use python && distutils-r1_src_install
+}