dev-cpp/mvfst: add 2025.04.14.00

RDEPEND fixed via qa-vdb.

Bug: https://bugs.gentoo.org/946922
Signed-off-by: sin-ack <sin-ack@protonmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

dev-cpp/mvfst/Manifest

@@ -1 +1,2 @@
 DIST mvfst-2024.11.04.00.gh.tar.gz 1983543 BLAKE2B 9c8b0da32baddd04af29e892a379333f89af45957a415dfa7f6da86f9a9b39fc8fbc73e450deb51e7a61b4ddfd37f08dc3d9ba8f48f83557aab4ae762068ec14 SHA512 4a000583884777fa876f3bfc52a3420c9cf8818f943c07898ac3b313837092fc173d8db497fd59027ef405d8fa5e3114a53b3bc5cf3fef398ca712c06a1da3e0
+DIST mvfst-2025.04.14.00.gh.tar.gz 2046690 BLAKE2B 7d8861d082b027b4c5b95cb755bc89907037b7e5e71be0bbb97806fa37d24bfec48979e1a8576c1c49b3007babe9e327c16d0d0971a66899e0a0ef9f373a8be7 SHA512 65fe3d5aee2ccffd0d459b3d07901c9d1085d6ec195d896ea66eb509ec1d662d4721b39242bab44ef10cafa479aae335a7a8904214871e28728857fc709061df

dev-cpp/mvfst/mvfst-2025.04.14.00.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# dev-cpp/edencommon
+# dev-cpp/fb303
+# dev-cpp/fbthrift
+# dev-cpp/fizz
+# dev-cpp/folly
+# dev-cpp/mvfst
+# dev-cpp/wangle
+# dev-util/watchman
+
+inherit cmake
+
+DESCRIPTION="An implementation of the QUIC transport protocol"
+HOMEPAGE="https://github.com/facebook/mvfst"
+SRC_URI="https://github.com/facebook/mvfst/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	~dev-cpp/fizz-${PV}:=
+	~dev-cpp/folly-${PV}:=
+	dev-cpp/gflags:=
+	dev-cpp/glog:=[gflags]
+	dev-libs/double-conversion:=
+	dev-libs/libfmt:=
+	dev-libs/openssl:=
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_MODULE_DIR="$(get_libdir)/cmake/${PN}"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_TESTS="$(usex test ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	if use arm64; then
+		# These tests segfault on arm64.
+		# https://github.com/facebook/mvfst/issues/363
+		CMAKE_SKIP_TESTS=(
+			QuicClientTransportIntegrationTest.ResetClient
+			QuicClientTransportIntegrationTest.TestStatelessResetToken
+		)
+	fi
+
+	cmake_src_test
+}