app-editors/mousepad: Bump to 0.6.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

app-editors/mousepad/Manifest

@@ -1 +1,2 @@
 DIST mousepad-0.6.0.tar.bz2 969433 BLAKE2B 690046e80f5cc74d928a8ea4d1ebcb513cf56dcaa3b295d5da528cbd139c36bc464a63a1c72acb833bcbb6f92c56b7f50f8222a3e2422d12b1f08188c12d75e0 SHA512 dad3488c973d767759a8b9752f83cc45d339064d34c19ee51f576af13f8db441f7234982c09e85f4032d553ee8df4f50ce8e0aa66c921a60ddb5c262a1c93702
+DIST mousepad-0.6.1.tar.bz2 1405279 BLAKE2B db94c433ba6dc697906258942abd0bcaa5a0a244c30c6e344e737944e84688045319551ebd1512aba541d87beafe5a8a26bb1265a06619aad64c7155140f33b3 SHA512 cf6ee9e32ecb1be9f1f54c587c4e8f653eb949f1103e378bf27959b88d8d6f268fb796285c8077bcef97926288cf941b9fb9426bfeb680ee728bddefa2d77d23

app-editors/mousepad/metadata.xml

@@ -5,4 +5,7 @@
 		<email>xfce@gentoo.org</email>
 		<name>XFCE Team</name>
 	</maintainer>
+	<use>
+		<flag name="shortcuts">Build the "shortcuts" plugin</flag>
+	</use>
 </pkgmetadata>

app-editors/mousepad/mousepad-0.6.1.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="GTK+-based editor for the Xfce Desktop Environment"
+HOMEPAGE="
+	https://docs.xfce.org/apps/mousepad/start
+	https://gitlab.xfce.org/apps/mousepad/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="policykit spell +shortcuts"
+
+DEPEND="
+	>=dev-libs/glib-2.56.2
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/gtksourceview-4.0.0:4
+	policykit? ( sys-auth/polkit )
+	spell? ( app-text/gspell )
+	shortcuts? ( >=xfce-base/libxfce4ui-4.17.5:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		--enable-gtksourceview4
+		$(use_enable policykit polkit)
+		$(use_enable spell plugin-gspell)
+		$(use_enable shortcuts plugin-shortcuts)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}