dev-python/ipykernel: Bump to 7.0.0_alpha0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/ipykernel/Manifest

@@ -1 +1,2 @@
 DIST ipykernel-6.29.5.tar.gz 163367 BLAKE2B ac1a48093b68a79c9b656cc3960f35ae2e28ac110b4a560b7434b853e37e505034d7822fc2d6557f03e1f82a260abba53cf53ba9dde4fc6fc468fd65fb46875a SHA512 271232ad6168ff00d6eb729bb38804f6a030b85be9bd75341b4af8ca1feb9f3c6b088eff77f4efcc503512559c93f1d78c13904089b7acb5205c4039daf0cea0
+DIST ipykernel-7.0.0a0.tar.gz 172248 BLAKE2B 7406cae0ce2543083850e3fdb362b5039386b5827a05c5829a5b4bbd0427d94d755c6abde1ced3099226fa6e684086d1923ec9d720e74669a4bbb4e8c80816d3 SHA512 047875f1fc84298e77478dd771a7dffbafb5b86cecccd9b1ef0295b9b60cd7fb1a407d41b4ad85ab3dc7e077f84f57359b2f464bbfd2a04e538ab357765eeb38

dev-python/ipykernel/ipykernel-7.0.0_alpha0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/anyio-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	>=dev-python/nest-asyncio-1.4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.7[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-25.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+# pytest-8 runs a small subset of tests, we allow newer for 3.13
+# since a few tests are better than skipping entirely
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# debugpy is actually optional
+	sed -i -e '/debugpy/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# hangs?
+		tests/test_eventloop.py::test_tk_loop
+		# flaky
+		tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				tests/test_embed_kernel.py
+				tests/test_kernelspec.py::test_install_kernelspec
+				tests/test_zmq_shell.py::test_zmq_interactive_shell
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p anyio -p timeout
+}