dev-python/werkzeug: Bump to 2.3.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-06-08 06:44:22 +02:00
parent 9ddd8e0195
commit d0b6fe21b3
2 changed files with 65 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST werkzeug-2.3.4.gh.tar.gz 833090 BLAKE2B e9d0134fa2a1355a2ef0df0f86cca6ea0f0a0c9b6ece98a6774ceab0a284c6a899e915688cb3e2e9f6192a7943cbcf20578d1e8f2f439dd8a9ab0f3d49361bcd SHA512 1e519fc88ac4438aa4dbd623ef8afc96a630df61d25a5a28154749f5c38593edefbb32163a632a5f38fa70d8cf2f1ae93633e54cfafe72d497ab70c99f9b2478
DIST werkzeug-2.3.5.gh.tar.gz 833927 BLAKE2B f9d2a81b0b1336265094df26d8b1fd17a471ed12d47014e5dd151085dd4112c0fb4788b62d926588d07dfaf91656d7e18406f5c684766e97bab45cccadea478e SHA512 d1c1e344efaa1c5aa04c71f8007a9f10b3043bf5db2459fddae8df5186b103de2fd3f61394dacb774b57a72feed7080cde1611040e0849c97d81e6ed1ee2c4b2
+64
View File
@@ -0,0 +1,64 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} pypy3 )
inherit distutils-r1
DESCRIPTION="Collection of various utilities for WSGI applications"
HOMEPAGE="
https://palletsprojects.com/p/werkzeug/
https://pypi.org/project/Werkzeug/
https://github.com/pallets/werkzeug/
"
SRC_URI="
https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="test-rust"
RDEPEND="
>=dev-python/markupsafe-2.1.1[${PYTHON_USEDEP}]
"
# NOTE: remove the loong mask after greenlet gains support for loong
# see https://github.com/python-greenlet/greenlet/pull/257
BDEPEND="
test? (
dev-python/ephemeral-port-reserve[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/pytest-xprocess[${PYTHON_USEDEP}]
>=dev-python/watchdog-2.3[${PYTHON_USEDEP}]
test-rust? (
dev-python/cryptography[${PYTHON_USEDEP}]
)
!hppa? ( !ia64? ( !loong? (
$(python_gen_cond_dep '
dev-python/greenlet[${PYTHON_USEDEP}]
' python3_{10..11})
) ) )
)
"
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=()
if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
"tests/test_serving.py::test_server[https]"
tests/test_serving.py::test_ssl_dev_cert
tests/test_serving.py::test_ssl_object
)
fi
# the default portage tempdir is too long for AF_UNIX sockets
local -x TMPDIR=/tmp
epytest -p no:django -p no:httpbin tests
}