gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 6.56.3

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-10-18 07:27:06 +02:00
parent f73c43d4c5
commit d073332db2
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -4,3 +4,4 @@ DIST hypothesis-6.55.0.gh.tar.gz 9330281 BLAKE2B 63f967496ed96e945579390d20eefb4
DIST hypothesis-6.56.0.gh.tar.gz 9330695 BLAKE2B bab11ea2c1e2e2a380557755890803ce0ac92b7a787e79799aec3d08ca802985acc49bbde4e71845f948035686f4ef92e8e6ad13083094b86a0aacf50bfcd424 SHA512 559dcf29252051c65c0729c4e7df1325c73027459cf41fb304a0f1752bd95ebb94cc613154663c02df15f12180066df3ff1b910e33c07fba78c74896984855aa
DIST hypothesis-6.56.1.gh.tar.gz 9333226 BLAKE2B c0cd31056cfa91632defa6db42fe3e153b2b2cfc21e7ddd93cc97e9298ffe71b516dcb90def11a9bb8fe4a4987a567c7d539a3a81a64553d3a31c775f9c038fe SHA512 73f7236f149b01170609f5010ce055bd0e451b5c1953866dd17de5afcc0b1852f7e80a199b31c5e22b4898e81bb666752f18e5c27af5feff64f23ac1b3e9568d
DIST hypothesis-6.56.2.gh.tar.gz 9333277 BLAKE2B 6c75b48cd6e7300c05bd020003340aa8c868ba2d25402c7599b0e4e6f8774df38e3b3c3a4b589cf08f44fb43b04cfdbc2a3e69f894c3ccaffef705896c6c0a98 SHA512 10d4cdd343b63bc17b3e813309911fa70dfee24fac5d355e6ed907740103177da9be461d4d25e27d5190867664c64f28a7827d6ffd15fa4519ea38fbcdf629e8
DIST hypothesis-6.56.3.gh.tar.gz 9333288 BLAKE2B 9608542d8dbe97fec147eae1f9b2f06af2b08e3cc0807fefcfa97b0a8c1aa30a15df9f1114a13f5c719701a4d13ab09a808d0d09e271d9e0d69168ebc4183af4 SHA512 f410455e77c6e9dc3b9003ef3d4c21bd204d85bc567dfd0d420986dc255d8c1ff9f41d809d837286f02064f546a08eff0f89389906ab7023581cc1f5a5d18947

77
dev-python/hypothesis/hypothesis-6.56.3.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{8..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!dev-python/requests-toolbelt
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}