gnome-extra/cinnamon-screensaver: add 6.0.3

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

gnome-extra/cinnamon-screensaver/Manifest

@@ -1,2 +1,3 @@
 DIST cinnamon-screensaver-5.6.3.tar.gz 157834 BLAKE2B 50728147fcb5849998113d5f19393e89f2cb4c5610359b81b42853fc2378814a52a8ed4f829cdd4e546a705a594da7b958ab25f69f996ee3d2204a64b7fdba90 SHA512 632bc9b518e59be7ce32c22ccfa32da060ea9edabe1683f91f2bf3c716fdcd7ca95fe4bda595ccc99821405bfbd987df2a416f229de56b3139f8d9975453ad39
 DIST cinnamon-screensaver-5.8.1.tar.gz 158825 BLAKE2B ebbbc0690f3a423b300a2be045fbf07953278992c48cc5182bc1b31944afb15a19103b13752adea64083d6cb14406b04610285e11b9f52f0aa48d9e9d1a41e15 SHA512 ac7523816be3d4b3a70afe0117e44b5cb42cd72f52534ca33ad0e3ab94f666d382d952a7c7842dd5dfd36520779695056775d243aee6df1845c7d90ccb7172ae
+DIST cinnamon-screensaver-6.0.3.tar.gz 161006 BLAKE2B 4f88cf0ca72384fbff2ce1f55047b6d53704bf55b2a3bfd5c942c19bcfbe9249c07e9fc1f08246c0e55c6b2110f543157ec87028789e58d752ff21d54d347ae2 SHA512 556b8eeac280001273460e5f1f5d1e5dbdf003ff95ad1ec9c3217316a6197520a32cd05d61a395daef066f13c8c9c89ebb9057779dd845bd597c207492fd91ef

gnome-extra/cinnamon-screensaver/cinnamon-screensaver-6.0.3.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="Screensaver for Cinnamon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-screensaver"
+SRC_URI="https://github.com/linuxmint/cinnamon-screensaver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ MIT"
+SLOT="0"
+IUSE="systemd xinerama"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2[dbus]
+	>=gnome-extra/cinnamon-desktop-6.0
+	sys-libs/pam
+	>=x11-libs/gtk+-3.22:3[introspection]
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/pango
+	x11-misc/xdotool
+	x11-themes/adwaita-icon-theme
+
+	xinerama? ( x11-libs/libXinerama )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=app-accessibility/caribou-0.3
+	sys-apps/accountsservice
+	sys-process/procps
+	x11-apps/xprop
+	$(python_gen_cond_dep '
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		>=dev-python/python3-xapp-2.4.1[${PYTHON_USEDEP}]
+	')
+
+	systemd? ( >=sys-apps/systemd-31 )
+	!systemd? ( sys-auth/elogind )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	sys-apps/dbus
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts src
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use xinerama)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize "${ED}"/usr/share/cinnamon-screensaver/
+}