media-libs/blib: EAPI6->8, fix aa+gtk automagic and build w/ clang16

This used `--disable-gtk2/aalib` when the options
actually are `--disable-gtk/aa`.

Also add several missing deps.

Closes: https://bugs.gentoo.org/874642
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

media-libs/blib/blib-1.1.7-r2.ebuild

@@ -1,45 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DESCRIPTION="blib is a library full of useful things to hack the Blinkenlights"
-HOMEPAGE="http://www.blinkenlights.de"
-SRC_URI="http://www.blinkenlights.de/dist/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="aalib gtk"
-
-RDEPEND="
-	>=dev-libs/glib-2:2
-	aalib? ( >=media-libs/aalib-1.4_rc4-r2 )
-	gtk? ( >=x11-libs/gtk+-2.4.4:2 )
-"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	default
-	# Drop DEPRECATED flags, bug #391105
-	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
-		blib/Makefile.am blib/Makefile.in \
-		gfx/Makefile.am gfx/Makefile.in \
-		modules/Makefile.am modules/Makefile.in \
-		test/modules/Makefile.am test/modules/Makefile.in || die
-}
-
-src_configure() {
-	econf \
-		--disable-directfb \
-		--disable-static \
-		$(use_enable aalib) \
-		$(use_enable gtk gtk2)
-}
-
-src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
-}

media-libs/blib/blib-1.1.7-r3.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Library full of useful things to hack the Blinkenlights"
+HOMEPAGE="http://www.blinkenlights.de"
+SRC_URI="http://www.blinkenlights.de/dist/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="aalib gtk"
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/gdk-pixbuf:2
+	aalib? ( media-libs/aalib )
+	gtk? (
+		app-accessibility/at-spi2-core:2
+		media-libs/fontconfig
+		media-libs/freetype
+		media-libs/harfbuzz:=
+		x11-libs/cairo
+		x11-libs/gtk+:2
+		x11-libs/pango
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-deprecated.patch
+)
+
+src_prepare() {
+	default
+
+	# drop DEPRECATED flags, bug #391105
+	sed -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
+		-i {blib,gfx,{,test/}modules}/Makefile.{am,in} || die
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable aalib aa)
+		--disable-directfb
+		$(use_enable gtk)
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}

media-libs/blib/files/blib-1.1.7-deprecated.patch

@@ -0,0 +1,14 @@
+This disables deprecated functions, then proceeds to use newly
+deprecated functions. Given GTK2 is now EOL and unchanging,
+there's no reason to avoid these without migration to newer GTK.
+
+https://bugs.gentoo.org/874642
+https://bugs.gentoo.org/391105 (see also)
+--- a/test/test-module.c
++++ b/test/test-module.c
+@@ -23,5 +23,4 @@
+ #include <string.h>
+ 
+-#define GTK_DISABLE_DEPRECATED
+ 
+ #include <gtk/gtk.h>