net-im/profanity: add 0.14.0

Signed-off-by: Michael Vetter <jubalh@iodoru.org>
Closes: https://github.com/gentoo/gentoo/pull/32153
Signed-off-by: Florian Schmaus <flow@gentoo.org>

net-im/profanity/Manifest

@@ -1 +1,2 @@
 DIST profanity-0.13.1.tar.xz 621836 BLAKE2B e038fa01272150cb7974b03f88f64335bf1690115dbbb1c6fe04c79acb69db18c556edf41316af1d363f9715cd2e7aeb3f3bd867836704b620d9a87976b64fa9 SHA512 6d7d3c96c65e26c15cac1157bd296c1dbd3e2471aec959d6c319c68b70ec21cef0c40d7b4eed40c30c377a766db9f13a774ccb4880c227ee368e4dd607d9c267
+DIST profanity-0.14.0.tar.gz 936272 BLAKE2B ec2ae625950a838ee50d6d3a87910bec76f28777bd662e909f394f18c277662694611a59d3be6c7f66821c2800a94b08f94b27a68d82e4de33b7d2f7b14ddf18 SHA512 25afd2f3146e6ed9f573f0e073cad0f06f7f8a21441c3c2c61641442d1aa5b9a7a817cdccc17354b32045ab9a965a95495a30c49088577a5060e8969725ea86e

net-im/profanity/profanity-0.14.0.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="https://profanity-im.github.io"
+SRC_URI="https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="libnotify omemo otr gpg test xscreensaver"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	|| ( app-accessibility/at-spi2-core:2 dev-libs/atk )
+	dev-libs/glib:2
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	>=dev-libs/libstrophe-0.12.3:=
+	media-libs/harfbuzz:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	x11-misc/shared-mime-info
+	virtual/libcrypt:=
+	gpg? ( app-crypt/gpgme:= )
+	libnotify? ( x11-libs/libnotify )
+	omemo? (
+		dev-libs/libgcrypt:=
+		net-libs/libsignal-protocol-c
+	)
+	otr? ( net-libs/libotr )
+	xscreensaver? (
+		x11-libs/libXScrnSaver
+		x11-libs/libX11
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-gdk-pixbuf
+		$(use_enable libnotify notifications)
+		$(use_enable omemo)
+		$(use_enable otr)
+		$(use_enable gpg pgp)
+		$(use_with xscreensaver)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}