gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

app-admin/tripwire: Bumps version to 2.4.3.6

Browse Source 
Package-Manager: Portage-2.3.8, Repoman-2.3.1
This commit is contained in:
Chema Alonso Josa
2017-10-02 18:03:08 +02:00
parent ec8a369768
commit cfb9e83296
2 changed files with 80 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
app-admin/tripwire/Manifest
View File

@@ -1 +1,2 @@
DIST tripwire-2.4.3.5.tar.gz 965014 SHA256 4bb0b400d8f5d7f8762ffb87a683f113f8c77186689cc63b8cedbbc628c9c33b SHA512 7aef0e7d38f4b6966a806a4e556636c7b2477f4ea5451e89f1749c1535a489c2f490ea13898edff5d7786acf572f77d04430115b8ddd4c6a03c38382feb45269 WHIRLPOOL f5f06d2f509e8047ede81226d3179f253e32aae4193817ab1000dd843f4b9810f6aacc6cd9c0bdc8a0c6835fdb11f79c85838a3b799d8c6565861d43dd433a99
DIST tripwire-2.4.3.6.tar.gz 1001145 SHA256 f55fe6805f2c159bd67fa3761ba52df95b2a7d0bdd06196847564bac00dd5606 SHA512 4757827b908fd56a014de81609be9cfdf3631d34cbc02214ac800bf6d9c413d85d812bc3211f9dc32ceee97e1f13decd955037a0cbbaf2f8e3020699492bd9bf WHIRLPOOL 0dad2b00a6e868179c1538ec48859a03857fa5bc62dcb9eb3240e11e10cd7ebf4de1fe85802c08abbf1ff1efca0768dcd63ff8088914f53f32cbf7fda20ec706

79
app-admin/tripwire/tripwire-2.4.3.6.ebuild Normal file
View File

@@ -0,0 +1,79 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools eutils flag-o-matic
DESCRIPTION="Open Source File Integrity Checker and IDS"
HOMEPAGE="http://www.tripwire.org/"
SRC_URI="https://github.com/Tripwire/tripwire-open-source/archive/${PV}.tar.gz -> ${PF}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="libressl selinux ssl static +tools"
DEPEND="sys-devel/automake
sys-devel/autoconf
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)"
RDEPEND="virtual/cron
virtual/mta
selinux? ( sec-policy/selinux-tripwire )
ssl? ( dev-libs/openssl )"
PDEPEND="tools? ( app-admin/mktwpol )"
S="${WORKDIR}/tripwire-open-source-${PV}"
src_prepare() {
default
eautoreconf
}
src_configure() {
# tripwire can be sensitive to compiler optimisation.
# see #32613, #45823, and others.
# -taviso@gentoo.org
strip-flags
append-cppflags -DCONFIG_DIR='"\"/etc/tripwire\""' -fno-strict-aliasing
econf $(use_enable ssl openssl) $(use_enable static)
}
src_install() {
dosbin "${S}"/bin/{siggen,tripwire,twadmin,twprint}
doman "${S}"/man/man{4/*.4,5/*.5,8/*.8}
dodir /etc/tripwire /var/lib/tripwire{,/report}
keepdir /var/lib/tripwire{,/report}
exeinto /etc/cron.daily
doexe "${FILESDIR}"/tripwire
dodoc ChangeLog policy/policyguide.txt TRADEMARK \
"${FILESDIR}"/tripwire.txt
insinto /etc/tripwire
doins "${FILESDIR}"/twcfg.txt policy/twpol-GENERIC.txt
fperms 750 /etc/cron.daily/tripwire
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]] ; then
elog "Tripwire needs to be configured before its first run. You can"
elog "do this by manually editing the twpol-GENERIC.txt file shipped with"
elog "the package to suit your needs. A quickstart guide is provided"
elog "in tripwire.txt file to help you with this."
elog "To configure tripwire automatically, you can use the twsetup.sh"
elog "script provided by the app-admin/mktwpol package. This package is"
elog "installed for you by the \"tools\" USE flag (which is enabled by"
elog "default."
else
elog "Maintenance of tripwire policy files as packages are added"
elog "and deleted from your system can be automated by the mktwpol.sh"
elog "script provided by the app-admin/mktwpol package. This package"
elog "is installed for you if you append \"tools\" to your USE flags"
fi
}