dev-python/httpcore: Backport >=dev-python/h11-0.14 support

Closes: https://bugs.gentoo.org/880117
Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/httpcore/Manifest

@@ -1 +1,2 @@
+DIST httpcore-0.15.0-h11-0.14.patch 7087 BLAKE2B 08a7b1a155392637cea9b6d59d01fc60b7a73416db9d87eb2477843cf6c46d1f4e342ce1b4b3ed362f0bf9d4dea7dca40dc7496c0b04a698c8924df7cbdb7f5f SHA512 9235d06a53b1839d7df945499f666477627dca5cbccde98b52d571d1d50380eb74b8d1b6538ea1cf5150062476780e5bf96290910c7c5513199d696f765a6868
 DIST httpcore-0.15.0.gh.tar.gz 76220 BLAKE2B e9a346d4f77cde82be5a3eb468123ae453753e57b54382f0b2c60b16afd3433cba173d9a796df20d76edbd8b5bcf2d61c32302bdd30c8d587036b3ac6f0425fd SHA512 3c25630d582448e3c7d46176c8862e4d92c6c4aac954bfe46b06e26297b32f996db2e002a87c7187accb5bf4ef86e82d7f9051404bee651ce5254119571d0c95

dev-python/httpcore/httpcore-0.15.0-r1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A minimal low-level HTTP client"
+HOMEPAGE="
+	https://www.encode.io/httpcore/
+	https://github.com/encode/httpcore/
+	https://pypi.org/project/httpcore/
+"
+SRC_URI="
+	https://github.com/encode/httpcore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	https://github.com/encode/httpcore/commit/4cf288e0007cb73561b9020af9228f076ba2a94e.patch
+		-> ${P}-h11-0.14.patch
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	=dev-python/anyio-3*[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	<dev-python/h11-0.15[${PYTHON_USEDEP}]
+	<dev-python/h2-5[${PYTHON_USEDEP}]
+	=dev-python/sniffio-1*[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-trio[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${DISTDIR}"/${P}-h11-0.14.patch
+)
+
+pkg_postinst() {
+	optfeature "SOCKS support" dev-python/socksio
+}