kde-apps/kalarm: 24.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-10 06:57:08 -08:00 · 2025-03-06 18:05:11 +01:00
parent 7fe8a73fb9
commit cfaabfa4d9
2 changed files with 90 additions and 0 deletions
@@ -1,2 +1,3 @@
 DIST kalarm-24.08.3.tar.xz 2619400 BLAKE2B f927a613da45e29ffe0f35c093c126cf97d067e4de5a43331332dcbab75cc17575a789c7fdb2b4a897336bbb17402461323425512ebefcf46691432581b6e966 SHA512 bb3ed33df9961b48681293e7adb1f65b0fec69f54bcb7bc76d219f941b97d8df448ed8f0bfc916178ecd05288de5f5401d503851d8a7b3a336c74d7ef55753f7
 DIST kalarm-24.12.2.tar.xz 2639044 BLAKE2B 9312d43264ff864ed6a679b9c0ebd63e8193551626d4ec36f95de23ead0a8c6d94fc2a50cf06123fbfa8c7f91777b7fe8cddda76dfccd5060c21167c7542d5c2 SHA512 e5eca1e41666b2bcec8bfaa5b2b722ad5bcd2926749dd2b6d5fe6f26c1643c34243558b488633639e2602b15ff404da2b54e098fdfbf6395183328016093441b
+DIST kalarm-24.12.3.tar.xz 2648416 BLAKE2B 16cbc23c6752d6fdf7befb458580387c8d02f48c538d8c719370d88ffd2b0837ee189e731cb99cda3c9a71bbe4599a7543f0e02804883a54b8ac842cdb986f3b SHA512 47945cfa9e2f1af590f7fcde523da04043331545eced9f7ba934f54609195013f4461e292901042e3ec28d60b337adae1da6e947afe0d9e2222fa1337e32c3ce
@@ -0,0 +1,89 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.7.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE="mpv +pim speech X"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+	>=kde-apps/kcalutils-${PVCUT}:6
+	>=kde-apps/kidentitymanagement-${PVCUT}:6
+	>=kde-apps/kmime-${PVCUT}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcalendarcore-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcontacts-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	mpv? ( >=media-video/mpv-0.37.0:=[libmpv] )
+	!mpv? ( media-video/vlc:= )
+	pim? (
+		>=kde-apps/akonadi-${PVCUT}:6
+		>=kde-apps/akonadi-contacts-${PVCUT}:6
+		>=kde-apps/akonadi-mime-${PVCUT}:6
+		>=kde-apps/kmailtransport-${PVCUT}:6
+	)
+	speech? ( >=dev-libs/ktextaddons-1.5.4:6[speech] )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${COMMON_DEPEND}
+	pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:6 )
+"
+# kde-apps/kidentitymanagement through its cmake module forces
+# kpimtextedit[speech=] in order not to break w/ kalarm[-speech]
+DEPEND="${COMMON_DEPEND}
+	>=kde-apps/kpimtextedit-${PVCUT}:6[speech=]
+	X? ( x11-base/xorg-proto )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_LIBMPV=$(usex mpv)
+		-DENABLE_LIBVLC=$(usex !mpv)
+		-DENABLE_AKONADI_PLUGIN=$(usex pim)
+		$(cmake_use_find_package speech KF6TextEditTextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# LC_TIME bug 665626, 857012
+	# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
+	LC_TIME="C" TZ=UTC ecm_src_test
+}