media-libs/zint: add 2.16.0

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/45100
Closes: https://github.com/gentoo/gentoo/pull/45100
Signed-off-by: Sam James <sam@gentoo.org>

media-libs/zint/Manifest

@@ -1 +1,2 @@
 DIST zint-2.15.0-src.tar.gz 6355115 BLAKE2B 15fd6521a504250f6c53e00790e162e1d2ad607dd9162288052b64eb695f62006ef8bb4f4024dacfd0fcfd50c66b0dd7826de2cdd2f7a86e3c522d81ec4a82f9 SHA512 7b5f44837a3a16637be5871ce848747ef520d623d86c88602c4ba8f0fe76705836ccee67a83e7ad0544e56b041dadbe88c5ed0b3219946be924213be18d74e2a
+DIST zint-2.16.0-src.tar.gz 6423511 BLAKE2B d3a8cf1f5810d248e643579a865aa4723f766bc4e36f67f7e23fa4918b5867d5b0066324b495d87302ba68dc69f485f95860984f65756b97c344ebb5faf21534 SHA512 f9148492e97550f1fb0d23fd611ead315a3b5c7f135feba88a00ea198216e9b0fef53f325e123d2705ca355ce2165863e1ea76aab560361e970b0da72c63136b

media-libs/zint/zint-2.16.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop dot-a xdg
+
+DESCRIPTION="Barcode encoding library supporting over 50 symbologies"
+HOMEPAGE="https://www.zint.org.uk/"
+SRC_URI="
+	https://downloads.sourceforge.net/${PN}/${P}-src.tar.gz
+"
+S="${WORKDIR}/${P}-src"
+
+# see LICENSE
+LICENSE="BSD GPL-3+"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~riscv"
+IUSE="gui png test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	gui? (
+		dev-qt/qtbase:6[gui,widgets]
+		dev-qt/qtsvg:6
+		dev-qt/qttools:6[widgets]
+	)
+	png? (
+		media-libs/libpng:=
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	lto-guarantee-fat
+
+	# Follow order in CMakeListst.txt
+	local mycmakeargs=(
+		-DZINT_TEST=$(usex test)
+		-DZINT_FRONTEND=ON
+		-DZINT_USE_GS1SE=OFF # unpackaged dependency
+		-DZINT_USE_PNG=$(usex png)
+		-DZINT_USE_QT=$(usex gui)
+		-DZINT_QT6=$(usex gui)
+		-DZINT_UNINSTALL=OFF
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	cmake_src_test -j1 # parallel tests cause failures to each other
+}
+
+src_install() {
+	cmake_src_install
+	einstalldocs
+	if use gui; then
+		domenu zint-qt.desktop
+		doicon zint-qt.png
+	fi
+
+	strip-lto-bytecode
+}