net-analyzer/gsad: add 22.9.1

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35404
Signed-off-by: Florian Schmaus <flow@gentoo.org>

net-analyzer/gsad/Manifest

@@ -1 +1,2 @@
 DIST gsad-22.9.0.tar.gz 224735 BLAKE2B da1ee149f6937ef2bb6d23391bf8594b776c8396d2a9fb0733b6d6933e1bd002ae560c178f8c300a09fd0d73c92615b750728fe8302f00b91e11926fe1a15aaa SHA512 ffe146a0dc87d2d95835dfa9b8eaeb2825a24aabe0f97e2ebd525235f96b23907476154fa52789c1d30d53daaf256743a4723db06e94bf6d4db98aaa57f08004
+DIST gsad-22.9.1.tar.gz 222663 BLAKE2B e65c8ecfa613a1653d36234d00e95da690e32c1c7ffc8904f509d568533079138115fcd389aaafa6d6cb96d5df42c9071e04edbbc95ea77731627ab7036adbde SHA512 25592b7e07357ff41f142cf926132491af20757a404773f3d532bafbf6e75d98b259103860920f657512d16a120351478767d347b01bef122ea1177c685d0d5b

net-analyzer/gsad/gsad-22.9.1.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake systemd toolchain-funcs
+
+DESCRIPTION="Greenbone Security Assistant"
+HOMEPAGE="https://www.greenbone.net https://github.com/greenbone/gsad"
+SRC_URI="https://github.com/greenbone/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="AGPL-3+"
+KEYWORDS="~amd64 ~x86"
+IUSE="brotli doc"
+
+DEPEND="
+	acct-user/gvm
+	>=net-libs/libmicrohttpd-0.9.0:=
+	dev-libs/libxml2:2
+	>=dev-libs/glib-2.42:2
+	>=net-analyzer/gvm-libs-22.6
+	>=net-libs/gnutls-3.2.15:=
+	>=sys-libs/zlib-1.2
+	dev-libs/libgcrypt:0=
+	brotli? (
+		app-arch/brotli
+	)
+"
+
+RDEPEND="
+	${DEPEND}
+	>=net-analyzer/gvmd-22.4
+	>=net-analyzer/gsa-22.4
+	net-analyzer/ospd-openvas
+"
+
+BDEPEND="
+	dev-python/polib
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen[dot]
+		app-text/xmltoman
+	)
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# QA-Fix | Remove !CLANG doxygen warnings for 9.0.0
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in
+		   do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DSBINDIR=${EPREFIX}/usr/bin"
+		"-DGSAD_RUN_DIR=${EPREFIX}/run/gsad"
+		"-DGVMD_RUN_DIR=${EPREFIX}/run/gvmd"
+		"-DSYSTEMD_SERVICE_DIR=$(systemd_get_systemunitdir)"
+		"-DLOGROTATE_DIR=${EPREFIX}/etc/logrotate.d"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	# setting correct PATH for finding react-js
+	NODE_ENV=production PATH="$PATH:${S}/gsa/node_modules/.bin/" cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	cmake_build rebuild_cache
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}/doc/generated/html/." )
+	fi
+	cmake_src_install
+
+	systemd_install_serviced "${FILESDIR}/gsad.service.conf" \
+			${PN}.service
+
+	insinto /etc/gvm/sysconfig
+	newins "${FILESDIR}/${PN}-daemon.conf" "${PN}-daemon.conf"
+
+	newinitd "${FILESDIR}/${PN}-22.init" "${PN}"
+	newconfd "${FILESDIR}/${PN}-daemon.conf" "${PN}"
+}