dev-lang/qore: bump to 1.19.1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

dev-lang/qore/Manifest

@@ -1 +1,2 @@
 DIST qore-1.19.0.tar.gz 3932880 BLAKE2B 8987a818e4fef495d9e07477715f18ad70541c81108bbc3aac56660e4d2ee9349303654ba07a849a7bfb43952d0ee8b868224f029254c83f435aa024def08669 SHA512 5264db098644ba39316e7825f1ed8243240c506a22c15836fcfa9500b173807ee9c4d213577d3a9eee7220d5d15ad171f05f75a431fb0537c95ab3dc761cbba3
+DIST qore-1.19.1.tar.gz 3933768 BLAKE2B 8e3002a55f1cf15f22ff604b1ceaf71995727510e365ae6ab03b71a91ddc1a82c5d6d89514b989a3509a5b39228fcf8fe11b6d88df8af784cace9b56b9d22482 SHA512 bf2203f8fe81cd4a604e06859380664f5cf635f5496e1ce6b6d5760d4cba82e510c78acef7ced4fdacd6df722f6eb305307106f12df3201003858a5a55256d9e

dev-lang/qore/qore-1.19.1.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Qore, the embeddable multithreaded scripting language"
+HOMEPAGE="http://qore.org/
+	https://github.com/qorelanguage/qore/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/qorelanguage/${PN}.git"
+else
+	SRC_URI="https://github.com/qorelanguage/${PN}/archive/release-${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-release-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+	app-arch/bzip2:=
+	dev-libs/libpcre:=
+	dev-libs/mpfr:=
+	dev-libs/openssl:=
+	sys-libs/zlib:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local -a myconf=(
+		--disable-optimization
+		--disable-profile
+		--disable-static-bz2
+		--disable-static-common
+		--disable-static-openssl
+		--disable-static-pcre
+		--disable-static-zlib
+		$(use_enable debug)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	PATH="${S}:${PATH}" emake check
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name "*.la" -delete ||
+		die "failed to remove libtool files without corresponding static libraries"
+}