gnome-extra/gnome-shell-extension-dash-to-panel: add 70

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

gnome-extra/gnome-shell-extension-dash-to-panel/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-shell-extension-dash-to-panel-68.tar.gz 21249885 BLAKE2B 3e6fb2a7e424dee20271974fc58d426408f92f343e01a21724b4b4dccb107ab25c49dd38b9452041cebe1afaf60a49c4b7854db0cc4bd271753138c373f48657 SHA512 38f689d0f256c9ba3ea28e096007fa03dc8eebff89ba56baaa8f78cce944f41289650d9d065b9481d649cfbf8c49a56f52353050e37d4ba0166af9ea81936453
+DIST gnome-shell-extension-dash-to-panel-70.tar.gz 21268362 BLAKE2B 10c0c34c72cbb2ffcea1edb305650fe4a42376f89cc1256e44d2bb0b225fcb8f6c3b1befb1ad4793b50329b6d558269446aec83f6e4158d71ca00395682083d0 SHA512 a82391caf65d3d62e74bf2a240e47885d21dd6fcb532ae09c440bf3c2d89c9e91f5e8d7a28dc6cd6c749bfdb3ba2ffcaa8c593448e6d9b07ccce18533b9adab0
 DIST tango-gentoo-v1.1.tar.gz 29322 BLAKE2B 83fa2bf37727e60851dd679054fe1b153ebfea58c9a9a40f891f7d68d3b047b02e8effa1d1b4e08d64500a2072ce7200f159c92a352da7124de27e1b05bb6027 SHA512 87d47ddab68361db6d99866c51705dcb3e198f8345a1096859acf2c6cca5099dd23c7fb30d124f52c4933ea38fd45fadffbbe6ecbdfa84f5b60938a4824f9045

gnome-extra/gnome-shell-extension-dash-to-panel/gnome-shell-extension-dash-to-panel-70.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils
+
+MY_PN="${PN/gnome-shell-extension-/}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="An icon taskbar for the Gnome Shell"
+HOMEPAGE="https://github.com/home-sweet-gnome/dash-to-panel"
+SRC_URI="
+	https://github.com/home-sweet-gnome/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	branding? ( https://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+S="${WORKDIR}/${MY_P}"
+extension_uuid="dash-to-panel@jderose9.github.com"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="branding"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-46
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+
+	# Set correct version
+	export VERSION="${PV}"
+
+	# Don't install README and COPYING in unwanted locations
+	sed -i -e 's/COPYING//g' -e 's/README.md//g' Makefile || die
+
+	# Provide fancy Gentoo icon when requested
+	use branding && eapply "${FILESDIR}"/${PN}-26-branding.patch
+}
+
+src_install() {
+	default
+	if use branding; then
+		insinto /usr/share/gnome-shell/extensions/dash-to-panel@jderose9.github.com/img
+		doins "${WORKDIR}/tango-gentoo-v1.1/scalable/gentoo.svg"
+	fi
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}