dev-python/kombu: 5.0.1 bump

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

dev-python/kombu/Manifest

@@ -1 +1,2 @@
 DIST kombu-4.6.8.tar.gz 406196 BLAKE2B 43ddb45e7e6a5bc1aff55867a816ebf7a1afed68bd41d9d74b6179a45d951ac4a4f0f687bbaebd23cf81b67fe2b81d47498b3e25eead0822e16d9acbb436338a SHA512 65b4ebb283ae380388de5d9f8fdc1ec0f41a9910744906b23eb150bc62ecb55ae6d65bb96ad31d8a033f26c2a8dc386939fced393866b6467e77a9760dfa17cc
+DIST kombu-5.0.1.tar.gz 404428 BLAKE2B 89d4c2daf70c3dcd0a990c8f045074780f2d4f13f39899c0ab3b73b473948469746cf8872aaa8565f5c4b071bf18ff510cd565e8f9b6a3735a0bf1d0af55e9b6 SHA512 aa5d35b7753f5ec8d95512c322fabf0163628b9afbd228faa2be910a1cd4ea3236a7e43485e17650e1aa9aebae59a91a2b0bdc1950e4e4c622b499a4ae29ea0e

dev-python/kombu/kombu-5.0.1.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+
+inherit distutils-r1
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples mongodb msgpack redis sqs test yaml"
+RESTRICT="!test? ( test )"
+
+# zookeeper backend support possible via dev-python/kazoo
+RDEPEND="
+	>=dev-python/importlib_metadata-0.18[${PYTHON_USEDEP}]
+	>=dev-python/py-amqp-2.6.0[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-2.7[${PYTHON_USEDEP}]
+	>=dev-python/pyro-4.76:4[${PYTHON_USEDEP}]
+	sqs? ( >=dev-python/boto3-1.4.4[${PYTHON_USEDEP}] )
+	msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )
+	mongodb? ( >=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}] )
+	redis? ( >=dev-python/redis-py-3.3.11[${PYTHON_USEDEP}] )
+	yaml? ( >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}] )"
+# Fix to https://github.com/celery/kombu/issues/474 obliges dev-python/pymongo to >=-3.0.2
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-20.6.7[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		<=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-1.1[${PYTHON_USEDEP}]
+	)"
+
+# kazoo is optional for tests.
+# Refrain for now, no established demand for it from users
+
+# Req'd for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+)
+
+python_prepare_all() {
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	rm t/unit/transport/test_etcd.py || die
+	# allow use of new (renamed) msgpack
+	sed -i '/msgpack/d' requirements/extras/msgpack.txt || die
+	# pytest-sugar is not packaged
+	sed -i '/pytest-sugar/d' requirements/test.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# Doc build misses and skips only content re librabbitmq which is not in portage
+	if use doc; then
+		emake -C docs html
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}