sys-auth/elogind: version bump 232.3

Package-Manager: Portage-2.3.6, Repoman-2.3.2

sys-auth/elogind/Manifest

@@ -1,2 +1,3 @@
 DIST elogind-229.6.tar.gz 765900 SHA256 19f08dba36509b3c5baf1f35d9ac1f5b473b550c081f63fa64ffbe8862ede7aa SHA512 a1bf2937ad2f8d351cd5a0ca5c1c73e85746d14e0a252befa3ed0d396e782df0fde34c49101931189cd56404b59709a7e5ae5beceaac6f30151b50fb32d26ae0 WHIRLPOOL 24d6315d4568b18df4eaa42410f2744b31ab935dd6a7fb0281e4fe2b2e953e411d462db829cbde786c338e823823998e13a9af287252440642499dfe8aca1b1c
 DIST elogind-231.4.tar.gz 812542 SHA256 6a7118abb696d6fd046bb4bbfcbc7bd415770792e6577417d9deb0bcbc4ee8ff SHA512 e1a031b8d6d4ad63043c79b5786b4b5dd890a7911483cdff8652242856edcad99ad811c44b132875a47ff8995d135d843cbfcf4622e4b3e2e7c62ad2d5acf90e WHIRLPOOL 8f5bbec56784eb95b3886c9eb42a9e1a233f68ff8107984e247612e4fd08443b88b69ab033b398fb2d77338ea69fa6607500d481a80a03810ab37a8613e7a703
+DIST elogind-232.3.tar.gz 834210 SHA256 6e1064fdc648e7ebe0aadbcc3c2b4e41f85fec08713dbca3faa5c156f8c76bbc SHA512 359949408549e102923954447c213ed060842846edd126ff233118405521ee553909efaa6ab8ed20c96786534e11b1f3b700e6db18232b7e69691d4712cf014d WHIRLPOOL 36eba13ce1891b40fc85f244b0cb2ca5ba1efbd1bd23fbc07220682706d4071ec15fcaa75ffce2241fd1da040dd207ef9655550cc5ade2962638223a9d126e29

sys-auth/elogind/elogind-232.3.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools linux-info pam udev
+
+DESCRIPTION="The systemd project's logind, extracted to a standalone package"
+HOMEPAGE="https://github.com/elogind/elogind"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="acl debug pam policykit selinux"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-libs/libcap
+	virtual/libudev:=
+	acl? ( sys-apps/acl )
+	pam? ( virtual/pam )
+	selinux? ( sys-libs/libselinux )
+	!sys-apps/systemd
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xml-dtd:4.5
+	app-text/docbook-xsl-stylesheets
+	dev-util/gperf
+	dev-util/intltool
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+PDEPEND="
+	sys-apps/dbus
+	policykit? ( sys-auth/polkit )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-226.4-docs.patch" )
+
+pkg_setup() {
+	local CONFIG_CHECK="~CGROUPS ~EPOLL ~INOTIFY_USER ~SECURITY_SMACK
+		~SIGNALFD ~TIMERFD"
+
+	if use kernel_linux; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf # Makefile.am patched by "${FILESDIR}/${P}-docs.patch"
+}
+
+src_configure() {
+	econf \
+		--with-pamlibdir=$(getpam_mod_dir) \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--with-rootlibdir="${EPREFIX}"/$(get_libdir) \
+		--enable-smack \
+		--with-cgroup-controller=openrc \
+		$(use_enable debug debug elogind) \
+		$(use_enable acl) \
+		$(use_enable pam) \
+		$(use_enable selinux)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+}
+
+pkg_postinst() {
+	if [ "$(rc-config list boot | grep elogind)" = "" ]; then
+		ewarn "To enable the elogind daemon, elogind must be"
+		ewarn "added to the boot runlevel:"
+		ewarn "# rc-update add elogind boot"
+	fi
+}