kde-frameworks/plasma: 5.99.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2022-10-10 10:14:30 +02:00
parent 78c71581e6
commit cdabbfeab2
2 changed files with 73 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST plasma-framework-5.96.0.tar.xz 3145380 BLAKE2B a9190358fc454dfba03d8f5881b52e21e7e209f471823d4d4ead54818103436775f09df7f1dd42ade4d4b5b2df448f5cb1bb682ea77d32c57cdfe7c39ecab238 SHA512 9361948197c69ab8b2a1b943c1e9a2e44443588cd3bb4073eaa9ac6a4575bb4c1e6a257eb2fda6333df13eb568e09ed26a88d128fdafbe517bca705b8a8f2a5b
DIST plasma-framework-5.98.0.tar.xz 3148664 BLAKE2B e61b896ed80a6f8b70846b19e2b9d525490ebbe4abb95d35f5663e93afbbc3ec23453e2228b20346c5961f6d6313c38f738150eca98f71d399670af3e07e0a88 SHA512 a016b5376ed620d4650c7581b282601c99aea2e6b7948d87f7a99bb747a3913ae2cc96a168deb7d25797fb9f936f4c76d05682036693a8515e756b7f20dab46d
DIST plasma-framework-5.99.0.tar.xz 3141664 BLAKE2B b37534440bc1f3d8f5fc13b6b62527c1bdde4b5d5d1c88530c49da2be221c9f55afac832cd8db61eb1bb91328145bc9b4c9e7b227b1ce740b10fa1bbefd3d2ef SHA512 bcf4f33facb20b542a90f5216fc0c5778d4de51d6a0ae86abdd5a22d7d1bfd7156dfd7a7d6cdad524b8f98596a75aa064fcbb295a36161ce288d4be4f42c5abb
@@ -0,0 +1,72 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
KDE_ORG_NAME="${PN}-framework"
PVCUT=$(ver_cut 1-2)
QTMIN=5.15.5
VIRTUALX_REQUIRED="test"
inherit ecm frameworks.kde.org
DESCRIPTION="Plasma framework"
LICENSE="LGPL-2+"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="gles2-only man wayland X"
RESTRICT="test"
RDEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5[gles2-only=,X=]
>=dev-qt/qtquickcontrols-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
=kde-frameworks/kactivities-${PVCUT}*:5
=kde-frameworks/karchive-${PVCUT}*:5
=kde-frameworks/kconfig-${PVCUT}*:5[qml]
=kde-frameworks/kconfigwidgets-${PVCUT}*:5
=kde-frameworks/kcoreaddons-${PVCUT}*:5
=kde-frameworks/kdeclarative-${PVCUT}*:5
=kde-frameworks/kglobalaccel-${PVCUT}*:5
=kde-frameworks/kguiaddons-${PVCUT}*:5
=kde-frameworks/ki18n-${PVCUT}*:5
=kde-frameworks/kiconthemes-${PVCUT}*:5
=kde-frameworks/kio-${PVCUT}*:5
=kde-frameworks/kirigami-${PVCUT}*:5
=kde-frameworks/knotifications-${PVCUT}*:5
=kde-frameworks/kpackage-${PVCUT}*:5
=kde-frameworks/kservice-${PVCUT}*:5
=kde-frameworks/kwidgetsaddons-${PVCUT}*:5
=kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
=kde-frameworks/kxmlgui-${PVCUT}*:5
!gles2-only? ( media-libs/libglvnd[X?] )
wayland? (
=kde-frameworks/kwayland-${PVCUT}*:5
media-libs/libglvnd
)
X? (
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libX11
x11-libs/libxcb
)
"
DEPEND="${RDEPEND}
X? ( x11-base/xorg-proto )
"
BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package !gles2-only OpenGL)
$(cmake_use_find_package man KF5DocTools)
$(cmake_use_find_package wayland EGL)
$(cmake_use_find_package wayland KF5Wayland)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}