media-sound/picard: bump to 2.12

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

media-sound/picard/Manifest

@@ -1 +1,2 @@
 DIST picard-2.11.tar.gz 5829423 BLAKE2B 1f5b675a3668b7545bbb5966e3d81bec09912acbe5ae7270b92eb25accf4bbd1cc67a2a183c6d1fa0300bb0adea5dbdcdc0998d2c44f60d2dbac941ca5af9fc8 SHA512 713a2782b26c4cd0dafa95b9c0b41bf3566d933ce9af712822cce0492ca8efa45ee57f1fb51aeacef824f699156a4156ee84ba91d5cfea28751e7d0f1e9a964a
+DIST picard-2.12.tar.gz 5857635 BLAKE2B 4eaec28830d85a0a45d220012fbb1acbfd40accc1536e47aa616b7d0014ef6f36111a6e9d6992862f9ff5419f7cb0c7b2b7b0a737ceca20bc804ce040f52ab22 SHA512 28f8d6b7b59a9a145404ab497a4ef0d71f2fefe86b9ec28b7f6879ec10f5ab1fd3582363bb15dd92c92c624843e87c11fce959fee75d0b312e72f6575d93b1a6

media-sound/picard/picard-2.12.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_EXT=1
+
+inherit distutils-r1 xdg
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/metabrainz/picard"
+	inherit git-r3
+else
+	SRC_URI="https://data.musicbrainz.org/pub/musicbrainz/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+DESCRIPTION="Cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="discid fingerprints nls"
+
+BDEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/fasteners[${PYTHON_USEDEP}]
+		dev-python/pyjwt[${PYTHON_USEDEP}]
+		dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
+		discid? ( dev-python/discid[${PYTHON_USEDEP}] )
+	')
+	fingerprints? ( media-libs/chromaprint[tools] )
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}