sys-cluster/galera: add 26.4.20

Signed-off-by: Petr Vaněk <arkamar@gentoo.org>

sys-cluster/galera/Manifest

@@ -1,2 +1,3 @@
 DIST galera-26.4.18.tar.gz 1542330 BLAKE2B 5a0d8b1929a72ce36f521ba3404b9251503226ba041970bc67f9d25b2b55c2daa2128500117366273541578eb1d7fd213d5f8336cba705650c55b70125dcbf0d SHA512 75ae75c0bac1b2ba5d0230af9b0e14b5e8661f20f84cee3800b2e979c3ef53c9dd5ce8cebcec1ae9205b5dec28f94f690854cce32a10e9f58d8aa55725fd59c6
 DIST galera-26.4.19.tar.gz 1548419 BLAKE2B fb4065a501412921d9a9b46cf9ce6cdd69616fe11a0cd9bbba17adb640af4f93d517514c31ccb00fbd7591ee624f6a4a6c1a9ba5552799276199cbb4fdb5bae4 SHA512 1d6e4d1adadbee411cb82335e4913bc28e009fa0e9ce150cf1d12cc85ce03cb00337ff52a6bad3a72315d42bf1daad1fe93b3fc810e109a762bb1a88f8c69cfe
+DIST galera-26.4.20.tar.gz 1551246 BLAKE2B 10231289b5c1adc6b4f427ed362877089c0b0de6cf78b5c1ef249fc37f5a407d539d98a9df12d1a5d33db5f6aeea88ec07a2729ba465649edef584fca9edb0e2 SHA512 35b2606c60a15bd5ba3fd5e9b921f96726def270f54225d8e2dc2ec6a563857c038229d1364d086283efaa6dd85973b0b1d061f8f81a353d9071585012627be9

sys-cluster/galera/galera-26.4.20.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN="${PN}-4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Synchronous multi-master replication engine that provides the wsrep API"
+HOMEPAGE="https://galeracluster.com"
+SRC_URI="
+	https://releases.galeracluster.com/${MY_PN}.$(ver_cut 3)/source/${MY_P}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="garbd ssl"
+
+RDEPEND="
+	ssl? ( dev-libs/openssl:= )
+	dev-libs/boost:=
+"
+# TODO: Make check dep optional
+DEPEND="
+	${RDEPEND}
+	>=dev-cpp/asio-1.22
+	dev-libs/check
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Remove bundled dev-cpp/asio
+	rm -r asio || die "Failed to remove bundled asio"
+
+	# Remove optional garbd daemon
+	if ! use garbd ; then
+		rm -r garb || die "Failed to remove garbd daemon"
+		sed -i '/add_subdirectory(garb)/d' CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DGALERA_WITH_SSL=$(usex ssl)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	dodoc scripts/packages/README scripts/packages/README-MySQL
+
+	if use garbd ; then
+		newconfd "${FILESDIR}"/garb.cnf garbd
+		newinitd "${FILESDIR}"/garb.init garbd
+		doman man/garbd.8
+
+		pushd "${BUILD_DIR}" || die
+		dobin garb/garbd
+	fi
+
+	pushd "${BUILD_DIR}" || die
+	exeinto /usr/$(get_libdir)/galera
+	doexe libgalera_smm.so
+}