mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-05 12:38:09 -07:00
gnome-extra/gnome-boxes: Version bump to 40.0
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Matt Turner
@@ -1 +1,2 @@
|
||||
DIST gnome-boxes-3.36.6.tar.xz 1275972 BLAKE2B a4b6bc98a8ed644020dce7ce5f5f08ae75291e2ac3351d1b3354d495a0579a59a245d63ba22754679b9641088bb71f96cd3abc7944f9996526ad7e6db9552458 SHA512 a37f34ea54d60d2d927dfe07a6ace6bd74910054b63a58bc2782f6dcd087d4a2153db0662d715a1bc67e2687742a162b3f66ff97b7678eb280f46b53765c7f73
|
||||
DIST gnome-boxes-40.0.tar.xz 1693528 BLAKE2B 15065fc28dcfa734ae2eea8b927042520466f56dd311b5328d224e220992b3db4ac24bca689a6f4d35c134721ba83ecb4f5a5a4760050a156069a45854c3218a SHA512 2ac569e5a423b67dc6b770eb754de6ce996e381032ce8610baf4de999dd45480eeba086211db783f440d465f3f50b06666c33e959270d8c87306e591b9aebeaf
|
||||
|
||||
129
gnome-extra/gnome-boxes/gnome-boxes-40.0.ebuild
Normal file
129
gnome-extra/gnome-boxes/gnome-boxes-40.0.ebuild
Normal file
@@ -0,0 +1,129 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
VALA_USE_DEPEND="vapigen"
|
||||
VALA_MIN_API_VERSION="0.40"
|
||||
|
||||
inherit gnome.org gnome2-utils linux-info meson readme.gentoo-r1 vala xdg
|
||||
|
||||
DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
|
||||
HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
|
||||
|
||||
LICENSE="LGPL-2+ CC-BY-2.0"
|
||||
SLOT="0"
|
||||
|
||||
IUSE="rdp"
|
||||
KEYWORDS="~amd64"
|
||||
|
||||
# FIXME: qemu probably needs to depend on spice[smartcard] directly with USE=spice
|
||||
# FIXME: Check over libvirt USE=libvirtd,qemu and the smartcard/usbredir requirements
|
||||
# Technically vala itself still ships a libsoup vapi, but that may change, and it should be better to use the .vapi from the same libsoup version
|
||||
# gtk-vnc raised due to missing vala bindings in earlier ebuilds
|
||||
DEPEND="
|
||||
>=app-arch/libarchive-3.0.0:=
|
||||
>=dev-libs/glib-2.52:2
|
||||
>=x11-libs/gtk+-3.24.1:3
|
||||
>=net-libs/gtk-vnc-0.8.0-r1[gtk3(+)]
|
||||
x11-libs/gtksourceview:4
|
||||
>=sys-libs/libosinfo-1.7.0
|
||||
app-crypt/libsecret
|
||||
>=net-libs/libsoup-2.44:2.4
|
||||
virtual/libusb:1
|
||||
>=app-emulation/libvirt-glib-4.0.0
|
||||
>=dev-libs/libxml2-2.7.8:2
|
||||
>=net-misc/spice-gtk-0.32[gtk3(+),smartcard,usbredir]
|
||||
app-misc/tracker:3
|
||||
>=net-libs/webkit-gtk-2.26.0:4
|
||||
>=gui-libs/libhandy-1.0.0:1=
|
||||
|
||||
>=dev-libs/gobject-introspection-1.56:=
|
||||
>=dev-libs/libgudev-165:=
|
||||
rdp? ( >=net-misc/freerdp-2.0.0:= )
|
||||
" # gobject-introspection needed for libovf subproject (and gtk-frdp subproject with USE=rdp)
|
||||
# These are called via exec():
|
||||
# sys-fs/mtools mcopy for unattended file copying for files that libarchive doesn't support
|
||||
# app-cdr/cdrtools mkisofs is needed for unattended installer secondary disk image creation
|
||||
# app-emulation/libguestfs virt-sysprep is used for VM cloing, if not there, it logs debug and doesn't function
|
||||
# sys-apps/policycoreutils restorecon is used for checking selinux context
|
||||
# app-emulation/libvirt virsh used for various checks (and we need the library anyways)
|
||||
# sys-auth/polkit used for making all libvirt system disks readable via "pkexec chmod a+r" that aren't already readable to the user (libvirt system importer)
|
||||
# app-emulation/qemu qemu-img used to convert image to QCOW2 format during copy
|
||||
RDEPEND="${DEPEND}
|
||||
app-cdr/cdrtools
|
||||
>=app-misc/tracker-miners-2[iso]
|
||||
app-emulation/spice[smartcard]
|
||||
>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
|
||||
>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
|
||||
sys-fs/mtools
|
||||
sys-auth/polkit
|
||||
"
|
||||
# gtk-frdp generates gir and needs gtk+ introspection for it
|
||||
# This is only needed for creating the .vapi file, but gnome-boxes needs it
|
||||
BDEPEND="
|
||||
$(vala_depend)
|
||||
net-libs/gtk-vnc[vala]
|
||||
sys-libs/libosinfo[vala]
|
||||
app-crypt/libsecret[vala]
|
||||
net-libs/libsoup:2.4[vala]
|
||||
app-emulation/libvirt-glib[vala]
|
||||
net-misc/spice-gtk[vala]
|
||||
x11-libs/vte:2.91[vala]
|
||||
dev-libs/appstream-glib
|
||||
rdp? ( x11-libs/gtk+:3[introspection] )
|
||||
dev-util/itstool
|
||||
>=sys-devel/gettext-0.19.8
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
DISABLE_AUTOFORMATTING="yes"
|
||||
DOC_CONTENTS="Before running gnome-boxes for local VMs, you will need to load the KVM modules.
|
||||
If you have an Intel Processor, run:
|
||||
# modprobe kvm-intel
|
||||
|
||||
If you have an AMD Processor, run:
|
||||
# modprobe kvm-amd"
|
||||
|
||||
pkg_pretend() {
|
||||
linux-info_get_any_version
|
||||
|
||||
if linux_config_exists; then
|
||||
if ! { linux_chkconfig_present KVM_AMD || \
|
||||
linux_chkconfig_present KVM_INTEL; }; then
|
||||
ewarn "You need KVM support in your kernel to use GNOME Boxes local VM support!"
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
xdg_src_prepare
|
||||
vala_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
-Ddistributor_name=Gentoo
|
||||
-Ddistributor_version=${PVR}
|
||||
$(meson_use rdp)
|
||||
-Dinstalled_tests=false
|
||||
-Dflatpak=false
|
||||
-Dprofile=default
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postrm
|
||||
gnome2_schemas_update
|
||||
}
|
||||
@@ -139,6 +139,7 @@ x11-misc/xstroke
|
||||
>=media-gfx/gnome-photos-40
|
||||
>=net-misc/rygel-0.40
|
||||
>=app-misc/bijiben-40
|
||||
>=gnome-extra/gnome-boxes-40
|
||||
|
||||
# Michał Górny <mgorny@gentoo.org> (2021-04-10)
|
||||
# Obsolete backport to Python < 3.4. No reverse dependencies left.
|
||||
|
||||
Reference in New Issue
Block a user