mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
games-emulation/dosbox-staging: 0.78.1 bump
Package-Manager: Portage-3.0.30, Repoman-3.0.3 Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
This commit is contained in:
@@ -2,3 +2,4 @@ DIST dosbox-staging-0.76.0.tar.gz 1908605 BLAKE2B 71b3c3d6a6444e2442d54b1db365ea
|
||||
DIST dosbox-staging-0.77.0.tar.gz 2579927 BLAKE2B 2a8381451ec110ca5350afc70c45f158329bd273b381ff61856ab721a0b194c7d501402453e9a36b90663ee8f6697dce8f64b05adf56efa8df2fd68161e420b6 SHA512 37259fecc091f1e318c2385d6e6fdc3b4ad0905ce63a7db1fc812c924bf8c01640692aca4f08b87d06e6001e50f3f2f4bb63c3715aa9cdfeebd205ed345558a0
|
||||
DIST dosbox-staging-0.77.1.tar.gz 2622418 BLAKE2B c56020d263ceac199266a5c458c192441f836ea2e71e1564da175b7ae522286ca1b6a07062498ccea795bbf330beecb5ef99a0130637b1df26603315d48ea6ff SHA512 fe5d6150a88f5c276aee5672f98c15b5ffee702fe9934919d3e78068efd1a85f08a8f04352bc6a8fe850324e33f3227340c59242db6cbae0475b12a58b749cac
|
||||
DIST dosbox-staging-0.78.0.tar.gz 2908118 BLAKE2B 77dd6afd7c8f62e2936c2ed1545faf1f2700b7bceba4afd6f77eff6b2bd1ea7b7693e3975d38098774f4f6076099251e7aa53cd20a5dec7daefb34a3533fdf40 SHA512 e56b4735f1a741f2c160646f205776e2407ab3333d4d13ce918ff447a08817862a32167afa47b3c7e35bc942bc06aea7d14e25bfe64fce9ee88a843488733746
|
||||
DIST dosbox-staging-0.78.1.tar.gz 2968448 BLAKE2B 7b48763d10338d36e61696331358f7572a528c10d48e473dfaba6a8c96dd5d3ca2b9e1f5c595d653fbbe64f2b5f1d9f1ff8279dfab8f2cb49ac6faba697e97ca SHA512 3179e8eac00e22e35b36623c11688b8c60408bf487a56683269ff065988fbdf4319c16097232cc191695cf2e10c05f4c4eee15e92d9887ebf03a23f808d5db7c
|
||||
|
||||
@@ -0,0 +1,66 @@
|
||||
# Copyright 2020-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
inherit meson xdg
|
||||
|
||||
DESCRIPTION="Modernized DOSBox soft-fork"
|
||||
HOMEPAGE="https://dosbox-staging.github.io/"
|
||||
SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="+alsa debug dynrec +fluidsynth mt-32 network opengl slirp test"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="alsa? ( media-libs/alsa-lib )
|
||||
debug? ( sys-libs/ncurses:0= )
|
||||
fluidsynth? (
|
||||
media-sound/fluid-soundfont
|
||||
media-sound/fluidsynth
|
||||
)
|
||||
mt-32? ( media-libs/munt-mt32emu )
|
||||
network? ( media-libs/sdl2-net )
|
||||
opengl? ( virtual/opengl )
|
||||
slirp? ( net-libs/libslirp )
|
||||
media-libs/libpng:0=
|
||||
media-libs/libsdl2[joystick,opengl?,video,X]
|
||||
media-libs/opusfile
|
||||
sys-libs/zlib
|
||||
!games-emulation/dosbox"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="test? ( dev-cpp/gtest )"
|
||||
|
||||
DOCS=( AUTHORS README THANKS )
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# We do not have default.sf2, use actual name from fluid-soundfont
|
||||
sed -e "s/default.sf2/FluidR3_GM.sf2/" \
|
||||
-i src/midi/midi_fluidsynth.cpp || die
|
||||
|
||||
# Disable license and docs install (handled by ebuild)
|
||||
sed -e "/licenses_dir\|doc_dir/d" -i meson.build || die
|
||||
|
||||
# Test failing on some platforms, bug #817908
|
||||
# https://github.com/dosbox-staging/dosbox-staging/issues/1230
|
||||
sed -i 's/.*soft_limit.*//' tests/meson.build || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_use alsa use_alsa)
|
||||
$(meson_use debug)
|
||||
-Ddynamic_core=$(usex dynrec dynrec dyn-x86)
|
||||
$(meson_use fluidsynth use_fluidsynth)
|
||||
$(meson_use mt-32 use_mt32emu)
|
||||
$(meson_use network use_sdl2_net)
|
||||
$(meson_use opengl use_opengl)
|
||||
$(meson_use slirp use_slirp)
|
||||
$(meson_feature test unit_tests)
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user