x11-libs/libdrm: Version bump to 2.4.97

Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-libs/libdrm/Manifest

@@ -1 +1,2 @@
 DIST libdrm-2.4.96.tar.bz2 829518 BLAKE2B d9a21ce31af65812c1b23968ef6c1901aea106b4cc68d76d3641a17b98423024b804bfda509862174eba98271bd7156c7f08d81bc0a520ea4a25c8e2e0bfd598 SHA512 008cb7658d953b44e11fa3cc6e00dfeb3efb59c7fdadd59f7066101aff138acbbc2f2508e9ebe0528340e39dc7693937755d1641816ddde135c10a13e7d81e3b
+DIST libdrm-2.4.97.tar.bz2 837329 BLAKE2B b47393d81917a0b43c22f7798ff2e1c21a05fc716a63092dbe0e49cda0fe3bd899d5cc4d703ae49f781e283f5067c62cd37a4931362427e21c3356584cb5e810 SHA512 3e08ee9d6c9ce265d783a59b51e22449905ea73aa27f25a082a1e9e1532f7c99e1c9f7cb966eb0970be2a08e2e5993dc9aa55093b1bff548689fdb465e7145ed

x11-libs/libdrm/libdrm-2.4.97.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/mesa/drm.git"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+inherit ${GIT_ECLASS} meson multilib-minimal
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="https://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://dri.freedesktop.org/libdrm/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+
+VIDEO_CARDS="amdgpu exynos freedreno intel nouveau omap radeon tegra vc4 vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms valgrind"
+RESTRICT="test" # see bug #236845
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="elibc_FreeBSD? ( >=dev-libs/libpthread-stubs-0.4:=[${MULTILIB_USEDEP}] )
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+
+src_unpack() {
+	default
+	[[ $PV = 9999* ]] && git-r3_src_unpack
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Udev is only used by tests now.
+		-Dudev=false
+		-Dcairo-tests=false
+		-Damdgpu=$(usex video_cards_amdgpu true false)
+		-Dexynos=$(usex video_cards_exynos true false)
+		-Dfreedreno=$(usex video_cards_freedreno true false)
+		-Dintel=$(usex video_cards_intel true false)
+		-Dnouveau=$(usex video_cards_nouveau true false)
+		-Domap=$(usex video_cards_omap true false)
+		-Dradeon=$(usex video_cards_radeon true false)
+		-Dtegra=$(usex video_cards_tegra true false)
+		-Dvc4=$(usex video_cards_vc4 true false)
+		-Detnaviv=$(usex video_cards_vivante true false)
+		-Dvmwgfx=$(usex video_cards_vmware true false)
+		-Dlibkms=$(usex libkms true false)
+		# valgrind installs its .pc file to the pkgconfig for the primary arch
+		-Dvalgrind=$(usex valgrind auto false)
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}

x11-libs/libdrm/libdrm-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6