mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
net-libs/webkit-gtk: bump to 2.18.2
Package-Manager: Portage-2.3.8, Repoman-2.3.2
This commit is contained in:
Mart Raudsepp
@@ -1,3 +1,4 @@
|
||||
DIST webkitgtk-2.16.6.tar.xz 14658120 SHA256 fc23650df953123c59b9c0edf3855e7bd55bd107820997fc72375811e1ea4b21 SHA512 bb488d7a60e4d6f9683ac343852a75854ef73e6b5aa093361ffe2d08e71e2f11c19da4447f9937221e518cda784bdacfcfd151f9395605a1957380fbc5b1533b WHIRLPOOL b3053979c1837d97ba525e078d4a14c64a66c61cb0117041af02c8fd250b2062fda66e782134d6bf44f3f80a04917a9b2ac61aa4e800f0011e5243d7eb8583f4
|
||||
DIST webkitgtk-2.18.1.tar.xz 14823708 SHA256 9cdb7b302fbc8a2a7e1e783b80391e64f8b12d70d6ebad4eb756dd59bf3ed795 SHA512 671392f46a34def51df34e5ce384acdcf7526b286e64f1220921f6c654a28148553e815f6f0fd02252b642dcabef9c646f5386b9ec3d2cb01520782833bb650b WHIRLPOOL e16e1e295d99d6589787fb51e2e3c5867877206428294b824307a5e7af43bdebeda3050a397fffee154c1a624fd21d59e25387fba58c91ce5ab30613773db056
|
||||
DIST webkitgtk-2.18.2.tar.xz 14823612 SHA256 b14cb3f1b5321b1dc50abcc0445a97f8e2f8813562bca7ce4d2f8069f6fec8e7 SHA512 94c8ce0fcee741dc9c054fa3f8ecac9756245c623f36e6b0bb5588d12b660aaa8bbbe28e82d0f694b94b75f1985f9dbf9231a4b63832fcf4efbe7a0116c7585c WHIRLPOOL a1ccd765d6699f07ecad8b4c899398bb2152076eda4f3a86af61d67c741229cf3d0ef02a7c8fbca2fb494e1bb1822518a18aa4f88026e91ebd2d4835d6807545
|
||||
DIST webkitgtk-2.4.11.tar.xz 9869100 SHA256 588aea051bfbacced27fdfe0335a957dca839ebe36aa548df39c7bbafdb65bf7 SHA512 2e2cf01a52b8593765a0a3c2d7f0ad306121660019eb402226bd2826c7d4666dab4e91ca6ccbd29abe0ad3993549f256ed1ab88de22e9c8516d5f40a4edd6bfb WHIRLPOOL de86c4abfb22aacbf62163d0398158931c9cf6ab628547d3b30e613f0505d67c85c3200f7db96500e7c2b35f640cdaa7f501346fc13f492c9439dff4056849a3
|
||||
|
||||
284
net-libs/webkit-gtk/webkit-gtk-2.18.2.ebuild
Normal file
284
net-libs/webkit-gtk/webkit-gtk-2.18.2.ebuild
Normal file
@@ -0,0 +1,284 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
CMAKE_MAKEFILE_GENERATOR="ninja"
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
USE_RUBY="ruby22 ruby23 ruby24"
|
||||
|
||||
inherit check-reqs cmake-utils eutils flag-o-matic gnome2 pax-utils python-any-r1 ruby-single toolchain-funcs versionator virtualx
|
||||
|
||||
MY_P="webkitgtk-${PV}"
|
||||
DESCRIPTION="Open source web browser engine"
|
||||
HOMEPAGE="http://www.webkitgtk.org/"
|
||||
SRC_URI="http://www.webkitgtk.org/releases/${MY_P}.tar.xz"
|
||||
|
||||
LICENSE="LGPL-2+ BSD"
|
||||
SLOT="4/37" # soname version of libwebkit2gtk-4.0
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos"
|
||||
|
||||
IUSE="aqua coverage doc +egl +geolocation gles2 gnome-keyring +gstreamer +introspection +jit libnotify nsplugin +opengl spell wayland +webgl X"
|
||||
|
||||
# webgl needs gstreamer, bug #560612
|
||||
REQUIRED_USE="
|
||||
geolocation? ( introspection )
|
||||
gles2? ( egl )
|
||||
introspection? ( gstreamer )
|
||||
nsplugin? ( X )
|
||||
webgl? ( ^^ ( gles2 opengl ) )
|
||||
!webgl? ( ?? ( gles2 opengl ) )
|
||||
webgl? ( gstreamer )
|
||||
wayland? ( egl )
|
||||
|| ( aqua wayland X )
|
||||
"
|
||||
|
||||
# Tests fail to link for inexplicable reasons
|
||||
# https://bugs.webkit.org/show_bug.cgi?id=148210
|
||||
RESTRICT="test"
|
||||
|
||||
# Aqua support in gtk3 is untested
|
||||
# Dependencies found at Source/cmake/OptionsGTK.cmake
|
||||
# Various compile-time optionals for gtk+-3.22.0 - ensure it
|
||||
# Missing OpenWebRTC checks and conditionals, but ENABLE_MEDIA_STREAM/ENABLE_WEB_RTC is experimental upstream (PRIVATE OFF)
|
||||
RDEPEND="
|
||||
>=x11-libs/cairo-1.10.2:=
|
||||
>=media-libs/fontconfig-2.8.0:1.0
|
||||
>=media-libs/freetype-2.4.2:2
|
||||
>=dev-libs/libgcrypt-1.6.0:0=
|
||||
>=x11-libs/gtk+-3.22:3[aqua?,introspection?,wayland?,X?]
|
||||
>=media-libs/harfbuzz-1.3.3:=[icu(+)]
|
||||
>=dev-libs/icu-3.8.1-r1:=
|
||||
virtual/jpeg:0=
|
||||
>=net-libs/libsoup-2.48:2.4[introspection?]
|
||||
>=dev-libs/libxml2-2.8.0:2
|
||||
>=media-libs/libpng-1.4:0=
|
||||
dev-db/sqlite:3=
|
||||
sys-libs/zlib:0
|
||||
>=dev-libs/atk-2.8.0
|
||||
media-libs/libwebp:=
|
||||
|
||||
>=dev-libs/glib-2.40:2
|
||||
>=dev-libs/libxslt-1.1.7
|
||||
gnome-keyring? ( app-crypt/libsecret )
|
||||
geolocation? ( >=app-misc/geoclue-2.1.5:2.0 )
|
||||
introspection? ( >=dev-libs/gobject-introspection-1.32.0:= )
|
||||
dev-libs/libtasn1:=
|
||||
>=dev-libs/libgcrypt-1.7.0:0=
|
||||
nsplugin? ( >=x11-libs/gtk+-2.24.10:2 )
|
||||
spell? ( >=app-text/enchant-0.22:= )
|
||||
gstreamer? (
|
||||
>=media-libs/gstreamer-1.2.3:1.0
|
||||
>=media-libs/gst-plugins-base-1.2.3:1.0
|
||||
>=media-libs/gst-plugins-bad-1.10:1.0[opengl?,egl?] )
|
||||
|
||||
X? (
|
||||
x11-libs/cairo[X]
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXt )
|
||||
|
||||
libnotify? ( x11-libs/libnotify )
|
||||
dev-libs/hyphen
|
||||
|
||||
egl? ( media-libs/mesa[egl] )
|
||||
gles2? ( media-libs/mesa[gles2] )
|
||||
opengl? ( virtual/opengl
|
||||
x11-libs/cairo[opengl] )
|
||||
webgl? (
|
||||
x11-libs/cairo[opengl]
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage )
|
||||
"
|
||||
|
||||
# paxctl needed for bug #407085
|
||||
# Need real bison, not yacc
|
||||
DEPEND="${RDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
${RUBY_DEPS}
|
||||
>=app-accessibility/at-spi2-core-2.5.3
|
||||
>=dev-lang/perl-5.10
|
||||
>=dev-util/gtk-doc-am-1.10
|
||||
>=dev-util/gperf-3.0.1
|
||||
>=sys-devel/bison-2.4.3
|
||||
|| ( >=sys-devel/gcc-4.9 >=sys-devel/clang-3.3 )
|
||||
sys-devel/gettext
|
||||
virtual/pkgconfig
|
||||
|
||||
dev-lang/perl
|
||||
virtual/perl-Data-Dumper
|
||||
virtual/perl-Carp
|
||||
|
||||
doc? ( >=dev-util/gtk-doc-1.10 )
|
||||
geolocation? ( dev-util/gdbus-codegen )
|
||||
introspection? ( jit? ( sys-apps/paxctl ) )
|
||||
test? (
|
||||
dev-lang/python:2.7
|
||||
dev-python/pygobject:3[python_targets_python2_7]
|
||||
x11-themes/hicolor-icon-theme
|
||||
jit? ( sys-apps/paxctl ) )
|
||||
"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
CHECKREQS_DISK_BUILD="18G" # and even this might not be enough, bug #417307
|
||||
|
||||
pkg_pretend() {
|
||||
if [[ ${MERGE_TYPE} != "binary" ]] ; then
|
||||
if is-flagq "-g*" && ! is-flagq "-g*0" ; then
|
||||
einfo "Checking for sufficient disk space to build ${PN} with debugging CFLAGS"
|
||||
check-reqs_pkg_pretend
|
||||
fi
|
||||
|
||||
if ! test-flag-CXX -std=c++11 ; then
|
||||
die "You need at least GCC 4.9.x or Clang >= 3.3 for C++11-specific compiler flags"
|
||||
fi
|
||||
|
||||
if tc-is-gcc && [[ $(gcc-version) < 4.9 ]] ; then
|
||||
die 'The active compiler needs to be gcc 4.9 (or newer)'
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
if [[ ${MERGE_TYPE} != "binary" ]] && is-flagq "-g*" && ! is-flagq "-g*0" ; then
|
||||
check-reqs_pkg_setup
|
||||
fi
|
||||
|
||||
python-any-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
# https://bugs.gentoo.org/show_bug.cgi?id=555504
|
||||
eapply "${FILESDIR}"/${PN}-2.8.5-fix-ia64-build.patch
|
||||
cmake-utils_src_prepare
|
||||
gnome2_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# Respect CC, otherwise fails on prefix #395875
|
||||
tc-export CC
|
||||
|
||||
# Arches without JIT support also need this to really disable it in all places
|
||||
use jit || append-cppflags -DENABLE_JIT=0 -DENABLE_YARR_JIT=0 -DENABLE_ASSEMBLER=0
|
||||
|
||||
# It does not compile on alpha without this in LDFLAGS
|
||||
# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=648761
|
||||
use alpha && append-ldflags "-Wl,--no-relax"
|
||||
|
||||
# ld segfaults on ia64 with LDFLAGS --as-needed, bug #555504
|
||||
use ia64 && append-ldflags "-Wl,--no-as-needed"
|
||||
|
||||
# Sigbuses on SPARC with mcpu and co., bug #???
|
||||
use sparc && filter-flags "-mvis"
|
||||
|
||||
# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
|
||||
use ppc64 && append-flags "-mminimal-toc"
|
||||
|
||||
# Try to use less memory, bug #469942 (see Fedora .spec for reference)
|
||||
# --no-keep-memory doesn't work on ia64, bug #502492
|
||||
if ! use ia64; then
|
||||
append-ldflags "-Wl,--no-keep-memory"
|
||||
fi
|
||||
|
||||
# We try to use gold when possible for this package
|
||||
# if ! tc-ld-is-gold ; then
|
||||
# append-ldflags "-Wl,--reduce-memory-overheads"
|
||||
# fi
|
||||
|
||||
# Multiple rendering bugs on youtube, github, etc without this, bug #547224
|
||||
append-flags $(test-flags -fno-strict-aliasing)
|
||||
|
||||
local ruby_interpreter=""
|
||||
|
||||
if has_version "virtual/rubygems[ruby_targets_ruby24]"; then
|
||||
ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby24)"
|
||||
elif has_version "virtual/rubygems[ruby_targets_ruby23]"; then
|
||||
ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby23)"
|
||||
elif has_version "virtual/rubygems[ruby_targets_ruby22]"; then
|
||||
ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby22)"
|
||||
else
|
||||
ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby21)"
|
||||
fi
|
||||
|
||||
# TODO: Check Web Audio support
|
||||
# should somehow let user select between them?
|
||||
#
|
||||
# FTL_JIT requires llvm
|
||||
#
|
||||
# opengl needs to be explicetly handled, bug #576634
|
||||
|
||||
local opengl_enabled
|
||||
if use opengl || use gles2; then
|
||||
opengl_enabled=ON
|
||||
else
|
||||
opengl_enabled=OFF
|
||||
fi
|
||||
|
||||
# support for webgl (aka 2d-canvas accelerating)
|
||||
local canvas_enabled
|
||||
if use webgl && ! use gles2 ; then
|
||||
canvas_enabled=ON
|
||||
else
|
||||
canvas_enabled=OFF
|
||||
fi
|
||||
|
||||
local mycmakeargs=(
|
||||
-DENABLE_QUARTZ_TARGET=$(usex aqua)
|
||||
-DENABLE_API_TESTS=$(usex test)
|
||||
-DENABLE_GTKDOC=$(usex doc)
|
||||
-DENABLE_GEOLOCATION=$(usex geolocation)
|
||||
$(cmake-utils_use_find_package gles2 OpenGLES2)
|
||||
-DENABLE_GLES2=$(usex gles2)
|
||||
-DENABLE_VIDEO=$(usex gstreamer)
|
||||
-DENABLE_WEB_AUDIO=$(usex gstreamer)
|
||||
-DENABLE_INTROSPECTION=$(usex introspection)
|
||||
-DENABLE_JIT=$(usex jit)
|
||||
-DUSE_LIBNOTIFY=$(usex libnotify)
|
||||
-DUSE_LIBSECRET=$(usex gnome-keyring)
|
||||
-DENABLE_PLUGIN_PROCESS_GTK2=$(usex nsplugin)
|
||||
-DENABLE_SPELLCHECK=$(usex spell)
|
||||
-DENABLE_WAYLAND_TARGET=$(usex wayland)
|
||||
-DENABLE_WEBGL=$(usex webgl)
|
||||
$(cmake-utils_use_find_package egl EGL)
|
||||
$(cmake-utils_use_find_package opengl OpenGL)
|
||||
-DENABLE_X11_TARGET=$(usex X)
|
||||
-DENABLE_OPENGL=${opengl_enabled}
|
||||
-DENABLE_ACCELERATED_2D_CANVAS=${canvas_enabled}
|
||||
-DCMAKE_BUILD_TYPE=Release
|
||||
-DPORT=GTK
|
||||
${ruby_interpreter}
|
||||
)
|
||||
|
||||
# Allow it to use GOLD when possible as it has all the magic to
|
||||
# detect when to use it and using gold for this concrete package has
|
||||
# multiple advantages and is also the upstream default, bug #585788
|
||||
# if tc-ld-is-gold ; then
|
||||
# mycmakeargs+=( -DUSE_LD_GOLD=ON )
|
||||
# else
|
||||
# mycmakeargs+=( -DUSE_LD_GOLD=OFF )
|
||||
# fi
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cmake-utils_src_compile
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# Prevents test failures on PaX systems
|
||||
use jit && pax-mark m $(list-paxables Programs/*[Tt]ests/*) # Programs/unittests/.libs/test*
|
||||
|
||||
cmake-utils_src_test
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
|
||||
# Prevents crashes on PaX systems, bug #522808
|
||||
use jit && pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/jsc" "${ED}usr/libexec/webkit2gtk-4.0/WebKitWebProcess"
|
||||
pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"
|
||||
use nsplugin && pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"2
|
||||
}
|
||||
Reference in New Issue
Block a user