sci-libs/symengine: version bump to 0.4

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

sci-libs/symengine/Manifest

@@ -1 +1,2 @@
 DIST symengine-0.3.0.tar.gz 629813 BLAKE2B 8d611703604f10d1ed8837708fa2125c0e84d12a8513d34e5d4bd44ae55395bcaa8fda92754b538ba1ecfdcacff83d079094dda9dfca6fdcdc4cccb0702cf484 SHA512 e4a906bb1cc5159003969871711f40b3c6bfb9e38ac25258dc5797933d55374a2f201c8a89e9af48821b24cc54408d4feb70f6de421e0a9fbf766d2b35846b83
+DIST symengine-0.4.0.tar.gz 753664 BLAKE2B c6296ceef20cfbb16803adc3c623429cf417c639d45d8cad742c3f7cf9d8171f22fb72e168cd07a6a705726a09133866fa497e2092ec4885ae4462d55adc416e SHA512 162c4bb4c67e2f21a0a113726d7b0ad00cc3e80db0534e95109a41894dcd05ca03a3be39d1a56a336b4bb7926dadad72fbe6705c71df3448db99fde20139ad11

sci-libs/symengine/symengine-0.4.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils flag-o-matic
+
+DESCRIPTION="Fast symbolic manipulation library, written in C++"
+HOMEPAGE="https://github.com/sympy/symengine"
+SRC_URI="https://github.com/sympy/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/0.4"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="arb benchmarks boost debug doc flint llvm mpc mpfr openmp test tcmalloc threads"
+
+RDEPEND="
+	dev-libs/gmp:=
+	sys-libs/binutils-libs:=
+	arb? ( sci-mathematics/arb:= )
+	boost? ( dev-libs/boost:= )
+	mpc? ( dev-libs/mpc:= )
+	tcmalloc? ( dev-util/google-perftools )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[dot] )
+"
+
+pkg_pretend() {
+	use openmp && [[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed -e "s|DESTINATION doc| DESTINATION share/doc/${PF}/html|" \
+		-e "s|/lib|/$(get_libdir)|g" \
+		-e "s|lib/|$(get_libdir)/|g" \
+		-e "/DESTINATION/s|lib|$(get_libdir)|g" \
+		-i CMakeLists.txt symengine/CMakeLists.txt \
+		symengine/utilities/teuchos/CMakeLists.txt || die
+}
+
+src_configure() {
+	# not in portage yet: piranha, ecm
+	local int_class
+	if use arb || use flint; then
+		int_class=flint
+	elif use mpfr; then
+		int_class=gmpxx
+	elif use boost; then
+		int_class=boostmp
+	else
+		int_class=gmp
+	fi
+	local mycmakeargs=(
+		-DARB_INCLUDE_DIR="${EPREFIX}/usr/include"
+		-DINTEGER_CLASS="${int_class}"
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_BENCHMARKS="$(usex benchmarks)"
+		-DBUILD_DOXYGEN="$(usex doc)"
+		-DBUILD_TESTS="$(usex test)"
+		-DWITH_ARB="$(usex arb)"
+		-DWITH_BFD="$(usex debug)"
+		-DWITH_SYMENGINE_ASSERT="$(usex debug)"
+		-DWITH_SYMENGINE_THREAD_SAFE="$(usex threads)"
+		-DWITH_FLINT="$(usex flint)"
+		-DWITH_OPENMP="$(usex openmp)"
+		-DWITH_MPFR="$(usex mpfr)"
+		-DWITH_MPC="$(usex mpc)"
+		-DWITH_LLVM="$(usex llvm)"
+		-DWITH_PTHREAD="$(usex threads)"
+		-DWITH_TCMALLOC="$(usex tcmalloc)"
+	)
+	test-flag-CXX -std=c++11 && append-cxxflags -std=c++11
+	CMAKE_BUILD_TYPE=Release cmake-utils_src_configure
+}