kde-apps/kwave: 24.05.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-08 18:27:07 -08:00 · 2024-06-13 18:49:49 +02:00
parent ff5869f10b
commit cd207c0ea8
2 changed files with 88 additions and 0 deletions
@@ -1,2 +1,3 @@
 DIST kwave-24.02.2.tar.xz 6983016 BLAKE2B ea09d082c9c83915f3fbbe2a9b61062c57eb456f31ad2660e66ae1327c6d4b43533115cfb9cf0dfbf16e32502eecff466ed4c560834b41e635d9c332ba7ef25c SHA512 e5c13588cbc8eee53b3825ddfcd7d1fa506e29613dba025ab7b13f7d328db2618eb2996a90715b0177a3c9a625bf97fd06a3b81ffc383352f1fc12691872991d
 DIST kwave-24.05.0.tar.xz 6551700 BLAKE2B e96bfaa3282d4843c147721b1d9b862772c0e5cefb130fd679e13cb87bd01c78f4cae2a81a325c2a9d12d39a307e571976f5416cc0861a37618aca99e2af8457 SHA512 6f112c0bcec6e5fc4e74fc684dabb6ab33822644e4a7e737e6936ad67fd663f0cf2c9ba64d6145167c3ba537d5c80fc0ee33eb7384637ace2149c7ecbb02c01b
+DIST kwave-24.05.1.tar.xz 6551780 BLAKE2B ab1fc2483b2386880b05ada836b41650bcb4a86143b29abdb47a4aaf59cbe90fd82912200d28458babea660240d6bbc9b1633465384d8754645eb80ba0eb442b SHA512 16c15705eb7ae60648897166d7de9b10b075dec65cea735ce89ac32899dfedf92e43158e3a496674f66c84ca1fcd138800825387675e76242388d32e17b82931
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.115.0
+QTMIN=5.15.12
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}