net-libs/libtorrent-rasterbar: add 2.0.10, enable py3.12 + tweak tests

Reenabled some tests which failed with previous versions, but are fixed
with 2.0.10: test_ssl [1], test_copy_file [2], test_create_torrent [3],
and disabled a test which fails randomly (test_remove_torrent)

[1] https://github.com/arvidn/libtorrent/issues/7565
[2] https://github.com/arvidn/libtorrent/issues/7566
[3] https://github.com/arvidn/libtorrent/issues/7567

Closes: https://bugs.gentoo.org/924415
Closes: https://bugs.gentoo.org/929708
Signed-off-by: Kostadin Shishmanov <kocelfc@tutanota.com>
Closes: https://github.com/gentoo/gentoo/pull/36398
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Kostadin Shishmanov
2024-05-03 12:01:54 +01:00
committed by Sam James
parent 0256d3a4f1
commit cd0700895f
2 changed files with 104 additions and 0 deletions
+1
View File
@@ -1,4 +1,5 @@
DIST libtorrent-rasterbar-1.2.18.tar.gz 4178407 BLAKE2B ccf8d891e4c34d101a8d822149d14b46cebf57dd893c00e2481e55c0cb35f6931b02e4b6f8877140316bb3bf1840a54eb04943aa1fd190d29708ae64a5c93604 SHA512 4ac7ad6357a612bdc537d4dbce40935a43c32295773870e490d1acffab9841b2bb3052e476a91f702b7b5eb2ab3e6282792f53593cdcb06ddbd6f1d5a3097ee7
DIST libtorrent-rasterbar-1.2.19.tar.gz 4244826 BLAKE2B 9983cc59d0a1ebfc92b9c1cdc992bd27cb2ae2cb39a71d9dac3ae20e66474b0ef1ad1b79bc8a1e4123a42215d148d8810c60dbf09a61ab786a89738392af492c SHA512 b427c03efc9601f57bcd0473064191f77fb73a25abcb006e332c7b4b9140158a2f866418363fc13f594d6bd836d1c8b3902e2bef60fc5579f2d0d0c267a18ecd
DIST libtorrent-rasterbar-2.0.10.tar.gz 4686014 BLAKE2B 8d1021cef16d338e10113ff8c514e5e2e5bc2ae0ec38da9448de16415c021623882ec09b005c1c86d73f13bd5d642f0cd08dd2ff9ea403a2fd633f7b5b808109 SHA512 a6406ccdd1d0c8d42543419a3b9edca880ab85e0849bfba29e3b1bd98f9630244aa3e88110cdf95e476792c9ea87a141fcb16a8c3b3e0c44c0076ebf6f9adbee
DIST libtorrent-rasterbar-2.0.8.tar.gz 4562750 BLAKE2B 6ea5855bd2e2d2ef56191ffea7bfc08a88ef43ffee177c1de12dbb62dc9167789abc5fcf2608856d5b23d5dc461fdc8d3f30c01286ce2ba9a11cb4d24fed477c SHA512 697988feae149876745097bedfbfb4cceae00ffe1cd4ba2063dcb93a8eee9e99344f772b8364e3df1986a50105e386e56b75fe362707d58ba3272139d9beb98f
DIST libtorrent-rasterbar-2.0.9.tar.gz 4720611 BLAKE2B 54de2dfba2bdc6c4341fddc54ce16d267b8aafde0218b262bfaa8d4c49dd28ef608a2500a572ee04c82a3e89b6322b0019405f8d9e03e8b31c6de9914f6d43a8 SHA512 c252dbe1e2a246769017b8a622bb3418527e2bc2615115ac2bff9662afb53759bc7b2cbf6657438c515ba6de0140fc1c388b340c48b3dd9f7e6202ec0df1aec7
@@ -0,0 +1,103 @@
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit cmake python-single-r1
DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="https://libtorrent.org/ https://github.com/arvidn/libtorrent"
SRC_URI="https://github.com/arvidn/libtorrent/releases/download/v${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+dht debug examples gnutls python ssl test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
DEPEND="
dev-libs/boost:=
ssl? (
gnutls? ( net-libs/gnutls:= )
!gnutls? ( dev-libs/openssl:= )
)
"
RDEPEND="
${DEPEND}
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-libs/boost[python,${PYTHON_USEDEP}]
')
)
"
BDEPEND="
dev-util/patchelf
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/setuptools[${PYTHON_USEDEP}]
')
)
test? (
${PYTHON_DEPS}
)
"
pkg_setup() {
# python required for tests due to webserver.py
if use python || use test; then
python-single-r1_pkg_setup
fi
}
src_configure() {
local mycmakeargs=(
-DCMAKE_CXX_STANDARD=17
-DBUILD_SHARED_LIBS=ON
-Dbuild_examples=$(usex examples)
-Ddht=$(usex dht)
-Dencryption=$(usex ssl)
-Dgnutls=$(usex gnutls)
-Dlogging=$(usex debug)
-Dpython-bindings=$(usex python)
-Dbuild_tests=$(usex test)
)
# We need to drop the . from the Python version to satisfy Boost's
# FindBoost.cmake module, bug #793038.
use python && mycmakeargs+=( -Dboost-python-module-name="${EPYTHON/./}" )
cmake_src_configure
}
src_test() {
CMAKE_SKIP_TESTS=(
# Needs running UPnP server
"test_upnp"
# Fragile to parallelization
# https://bugs.gentoo.org/854603#c1
"test_utp"
# Flaky test, fails randomly
"test_remove_torrent"
)
LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" cmake_src_test
}
src_install() {
cmake_src_install
einstalldocs
if use examples; then
pushd "${BUILD_DIR}"/examples >/dev/null || die
for binary in {client_test,connection_tester,custom_storage,dump_bdecode,dump_torrent,make_torrent,simple_client,stats_counters,upnp_test}; do
patchelf --remove-rpath ${binary} || die
dobin ${binary}
done
popd >/dev/null || die
fi
}